分割字符串函数导致堆栈溢出

Question

我有一个函数可以将字符串分割成长度不超过 76 个字符的行。该函数的输入是二进制数据，我想由于二进制数据的长度，我经常收到“堆栈溢出”错误。有什么方法可以防止这种情况，或者有更好的方法来分割字符串吗？这需要使用 XSL 1.0 来完成。

<xsl:template name="splitBinaryData">
    <xsl:param name="txt"/>
    <xsl:param name="width"/>
    <xsl:choose>
        <xsl:when test="string-length($txt) &gt; 76 ">
            <xsl:value-of select="substring($txt, 1, 76)"/><xsl:text>&#10;</xsl:text>
            <xsl:call-template name="splitBinaryData">
                <xsl:with-param select="substring($txt, 77)" name="txt"/>
                <xsl:with-param select="$width" name="width"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:when test="string-length($txt) &lt; 76 or string-length($txt) = 76">
            <xsl:value-of select="$txt"/>
        </xsl:when>
    </xsl:choose>
</xsl:template>

提前致谢。

Answer 1

一种可能是将算法转换为尾递归，并希望您的 xslt 处理器能够识别该模式并将其变成一个循环。除了 saxon 之外，我找不到其他 xslt 处理器支持尾递归的任何信息。该转换通过引入包含分割文本的累加器变量来进行。 call-template 指令将成为模板必须执行的最后一个操作，并且可以转换为相当于 goto 的操作，而无需消耗任何堆栈。

<xsl:template name="splitBinaryData">
    <xsl:param name="txt"/>
    <xsl:param name="width"/>
    <xsl:param name="accum"/>
    <xsl:choose>
        <xsl:when test="string-length($txt) > 76 ">
            <xsl:call-template name="splitBinaryData">
                <xsl:with-param select="substring($txt, 77)" name="txt"/>
                <xsl:with-param select="$width" name="width"/>
                <xsl:with-param select="concat($accum, substring($txt, 1, 76), '
')" name="accum"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:when test="string-length($txt) < 76 or string-length($txt) = 76">
            <xsl:value-of select="concat($accum, $txt)"/>
        </xsl:when>
    </xsl:choose>
</xsl:template>

编辑：另一种选择是应用分而治之类型算法。这将问题分成两个大小大致相等的子问题，然后组合它们的解决方案。所需的堆栈深度大大减少，并且与输入大小呈对数增长，而不是线性增长。这里的技巧是使第一个子字符串的大小为 76 个字符的倍数，以避免插入额外的换行符。

<xsl:template name="splitBinaryData">
    <xsl:param name="txt"/>
    <xsl:param name="width"/>
    <xsl:variable name="len" select="string-length($txt)" />
    <xsl:choose>
        <xsl:when test="$len > 76 ">
            <!-- process the text in two parts of about the same size,
                 the length of the first part should be a multiple of
                 the needed width -->
            <xsl:variable name="idx" select="ceiling($len div 76 div 2) * 76" />
            <xsl:call-template name="splitBinaryData">
                <xsl:with-param select="substring($txt, 1, $idx)" name="txt"/>
                <xsl:with-param select="$width" name="width"/>
            </xsl:call-template>
            <xsl:text>
</xsl:text>
            <xsl:call-template name="splitBinaryData">
                <xsl:with-param select="substring($txt, $idx+1)" name="txt"/>
                <xsl:with-param select="$width" name="width"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$txt" />
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

Answer 2

使用“分而治之”模式，例如：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="/" name="splitBinaryData">
        <xsl:param name="txt" select="string()"/>
        <xsl:param name="width" select="5"/>
        <xsl:param name="length" select="string-length()"/>
        <xsl:choose>
            <xsl:when test="$length > $width">
                <xsl:variable name="split"
                 select="ceiling($length div $width div 2) * $width"/>
                <xsl:call-template name="splitBinaryData">
                    <xsl:with-param name="txt"
                     select="substring($txt, 1, $split)"/>
                    <xsl:with-param name="width" select="$width"/>
                    <xsl:with-param name="length" select="$split"/>
                </xsl:call-template>
                <xsl:call-template name="splitBinaryData">
                    <xsl:with-param name="txt"
                     select="substring($txt, $split + 1)"/>
                    <xsl:with-param name="width" select="$width"/>
                    <xsl:with-param name="length" select="$length - $split"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="concat($txt, '
')"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

注意：MSXSL 4 在 XHTML 格式 (1.4 MB) 在我的机器上只需 2 秒。