当 XPath 本身是节点内的文本时从节点获取值

Question

简单的问题：我有一个像这样的 XML 文件：

<Locations>
    <Location>/Simulation/@ID</Location>
    <Location>/Simulation/Loans</Location>
    <Location>/Simulation/Assets</Location>
    <Location>/Simulation/BankAssets</Location>
    <Location>/Simulation/RealEstates</Location>
</Locations>

我还有第二个 XML 文件，其中包含与这些 XPath 节点匹配的数据。我需要创建一个 XSLT 1.0，无需任何脚本来转换此数据文件以生成与这些节点匹配的数据列表。像这样的事情：

<Data>
    <Item Node="/Simulation/@ID">
        <Value>1</Value>
        <Value>2</Value>
        <Value>3</Value>
    </Item>
    <Item Node="/Simulation/Loans">
        <Value>1024</Value>
        <Value>555</Value>
        <Value>0</Value>
    </Item>
</Data>

每个项目的值节点数量并不重要。不同项目的值之间的关系也不重要。基本上，样式表只是为了收集简单的统计数据以进行总结、平均等等。 货车的位置列表有很大差异，具体取决于用户的需求。这个例子只是一些欺骗数据。

问题：如何收集这些信息？

Answer 1

实际上有两种方法可以做到这一点 - 一种是执行两阶段转换，另一种是使用evaluate扩展函数。

两阶段转换

首先，您需要根据您的 Locations 列表生成正确的 XSL。它可能看起来像这样：

<xsl:template match="/">
    <Data>
        <Item Node="/Simulation/@ID">
            <xsl:apply-templates select="/Simulation/@ID"/>
        </Item>
        <Item Node="/Simulation/Loans">
            <xsl:apply-templates select="/Simulation/Loans"/>
        </Item>

        <!-- ... and so on ... -->

    </Data>
</xsl:template>

<xsl:template match="node()|@*">
    <Value>
        <xsl:value-of select="."/>
    </Value>
</xsl:template>

我假设您在创建将根据您的 XPath 定义文件生成此输出的转换方面没有太多麻烦，因为模式非常简单。

下一步是将生成的转换应用到源文件。您可以将这两个步骤组合成小管道并获得您想要的结果。

使用扩展函数

EXSLT 库包含名为 evaluate 这对像你这样的情况有帮助。据我所知，Xalan 变压器支持它，但 Saxon 不支持它。
然而，此功能存在一个主要问题 - 从 Xalan 2.7 版本开始，存在一个 bug 防止执行多重评估。不幸的是，当我尝试运行下面的样式表时，它受到了影响。如果可能的话，建议将 Xalan 版本更改为 2.6。尽管如此，这里的样式表可以完成您想要的操作，而无需额外的生成阶段。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:dyn="http://exslt.org/dynamic" extension-element-prefixes="dyn">

    <xsl:variable name="locations" select="document('xpath.xml')/Locations"/>
    <xsl:variable name="root" select="/"/>

    <xsl:template match="/">
        <Data>
            <xsl:for-each select="$locations/Location">
                <Item Node="{.}">
                    <xsl:variable name="currentLocation" select="concat('$root', .)"/>
                    <xsl:apply-templates select="dyn:evaluate($currentLocation)"/>
                </Item>
            </xsl:for-each>
        </Data>
    </xsl:template>

    <xsl:template match="node()|@*">
        <Value>
            <xsl:value-of select="."/>
        </Value>
    </xsl:template>

</xsl:stylesheet>

假设具有位置定义的文档位于同一目录中，并且名为 xpath.xml。如果情况并非如此，请更新 document() 函数用法。