如何避免使用“strict”时产生的此错误？

Question

如果 use strict; 被注释掉，我有几行代码可以工作。但是，我不想仅仅因为一小部分就禁用整个脚本。

我需要重新编码它，或者以某种方式暂时禁用 use strict; 然后重新启用它。第一个选项更现实，但我不知道如何更改代码以在严格模式下工作。

my ($ctc_rec_ref) = get_expected_contacts($ctc,$fy);

my @expected_ctc_rec = @$ctc_rec_ref;

print $expected_ctc_rec[0][0]."\n";
print $expected_ctc_rec[0][1]."\n";
print $expected_ctc_rec[0][2]."\n";

sub get_expected_contacts
{
    my (@ctc_rec,$i) = ((),0);
    $STMT = "SELECT DISTINCT field1, field2, field3 FROM table WHERE field4 = ? AND field5 = ? AND field6 = 'E'";
    $sth = $db1->prepare($STMT); $sth->execute(@_); 
    while(@results = $sth->fetchrow_array())
    {
        push @{ $ctc_rec[$i] }, $results[0];
        push @{ $ctc_rec[$i] }, $results[1];
        push @{ $ctc_rec[$i] }, $results[2];

        $i++;
    }   
    return (\@ctc_rec);
}

---

With use strict; enabled:

无法使用字符串（“0”）作为 ARRAY 引用 而“严格裁判”在使用 ./return5.pl 第 49 行。

（第 49 行：push @{ $ctc_rec[$i] }, $results[0];）

禁用 use strict; 时：

1468778 
04/01/2011 
30557

---

如何重写此代码，使其像禁用严格模式一样工作？如果这是不可能的，是否可以暂时禁用 use strict; ，然后重新启用脚本中的这段简短代码？

Answer 1

问题在于 @ctc_rec 和 $i 的声明。 错误：

试试这个，你的代码应该停止给出来自 strict: Replace:

my (@ctc_rec,$i) = ((),0);

With: 的

my @ctc_rec;
my $i = 0;

Answer 2

问题是它

my (@ctc_rec,$i) = ((),0);

并没有按照你的想法去做。这与 strict 的意思相同，

my @ctc_rec = (0);
my $i;

就是做它应该做的事情并发现你的错误。尝试写：

my @ctc_rec;
my $i = 0;

代替。这应该消除错误。

在这种情况下，还有另一种方法可以消除错误，同时大大简化代码：使用 selectall_arrayref。

sub get_expected_contacts
{
   return $db1->selectall_arrayref(
     "SELECT DISTINCT field1, field2, field3 FROM table WHERE field4 = ? AND field5 = ? AND field6 = 'E'",
     undef, @_
   );
}

如果您确实有意执行 strict 所禁止的操作（但知道自己在做什么），则可以在本地禁用 strict：

use strict;

# this code is strict
{ 
  no strict;
  # some code that is not strict here
}
# strict is back in effect now

但在您了解之前切勿这样做strict 到底在抱怨什么，以及为什么在这种情况下可以这样做。最好只禁用您必须禁用的 strict 部分。例如，您可以使用 no strict 'refs'; 来允许符号引用，而不禁用 strict 执行的其他操作。 （注意：同样的技术适用于 warnings 编译指示，您也应该使用它。）