访问动态添加的MC中的实例

Question

我使用以下代码动态添加了一个影片剪辑：

var apie=new cPie()
apie.x=100
apie.y=100
stage.addChild(apie)

现在我的舞台上有一个馅饼。嗯。假设这就像通过拖放放置在舞台上的影片剪辑一样，我添加了它来更改饼中的实例。

var apie=new cPie()
apie.x=100
apie.y=100
apie.cherry.gotoAndStop(2)
stage.addChild(apie)

cherry 是 cPie 影片剪辑中的一个实例，cPie 影片剪辑是另一个由 3 帧组成的影片剪辑。我希望它进入第二帧。通常，这样做是可行的，但是当尝试通过 ActionScript 添加影片剪辑时，我会遇到以下运行时错误：

TypeError: Error #1009: Cannot access a property or method of a null object reference.
    at pies_fla::MainTimeline/frame1()

与往常一样，返回的错误根本无法帮助我解决此问题。这就像“隐性强制”一样晦涩难懂，这对我不是英语专业的人来说毫无意义。我所知道的是我做错了什么，结果我得到了这个错误。解决这个问题的正确方法将非常感激。

PS 我打算循环使用它。请考虑到这一点。

Answer 1

我认为该错误是由 apie.cherry.gotoAndStop(2) 行引起的。您可能必须将其更改为 apie.getChildByName("cherry").gotoAndStop(2) 但由于您的饼图是一个影片剪辑，因此子项通常不会立即实例化。

解决这个问题的一种方法是在尝试访问 MovieClip 的子级之前等待帧重绘。

Answer 2

您收到该错误的原因是 cherry 不是 cPie 对象的属性或方法，它是 cPie 的子显示对象的实例名称 显示对象容器。要访问 cherry 显示对象，您必须使用 cPie 对象继承的 DisplayObjectContainer 方法，即 getChildByName()方法。幸运的是，frankhermes 已经在另一个答案中对此进行了解释，因此我将在以下示例中解释另一种（并且可以说是更好的）访问子显示对象的方法：

CherryPie.as：

package display
{
    import flash.display.MovieClip;

    public class CherryPie extends MovieClip
    {
        private var _cherry:MovieClip;

        public function get cherry():MovieClip
        {
            return _cherry;

        }// end function

        public function CherryPie()
        {
            _cherry = cherryMC;

        }// end function

    }// end class

}// end package

Main.as：

package 
{
    import flash.display.Sprite;
    import flash.events.Event;

    public class Main extends Sprite 
    {
        public function Main():void 
        {
            init();

        }// end function

        private function init():void 
        {
            var cherryPie:CherryPie = new CherryPie();
            cherryPie.x = 100;
            cherryPie.y = 100;
            cherryPie.cherry.gotoAndStop(2);
            addChild(cherryPie);

        }// end function

    }// end class

}// end package

通过为您的cherryPie_mc 影片剪辑中，您可以创建一个名为 cherry 的属性，并在启动类时将 cherry 子显示对象分配给它。通过这种方式，您可以直接访问 cherry 子显示对象，如下所示：

cherryPie.cherry.gotoAndStop(2);

与以下方式相反：

cherryPie.getChildByName("cherryMC").gotoAndStop(2);

您可以将 CherryPie 类设置为 cherryPie_mc 影片剪辑的基础类如下：

注意：交易品种属性中的“名称”应为“cherryPie_mc”

也适合那些想知道为什么我没有将 cherry 设置为公共属性的

public var cherry:MovieClip;

人使用 getter 方法访问私有属性的

private var _cherry:MovieClip;

public function get cherry():MovieClip
{
    return _cherry;

}// end function

目的是使 Cherry 对象变为只读，这是通过省略 setter 方法来完成的。我将其设置为只读的原因是为了避免出现以下情况：

cherryPie.cherry = new FakeCherry();