在 Coffeescript 中枚举和压缩？

Question

来自 Python，我喜欢 Coffeescript 从 Python 和 Perl 借用的许多功能（范围/切片、推导式、解构赋值）。 Coffeescript 中是否有任何语法糖可以模仿 Python 的 enumerate 或 zip (itertools.izip) 函数？

以下是我不太关心的模式：

# an enumerate call would be helpful here
i = 0
for x in arr
  ... use x and i ...
  i++

和

# a zip would be useful here
n = Math.min(arr1.length,arr2.length)
for i in 0...n
  x = arr1[i]; y = arr2[i]
  ... use x and y ...

Answer 1

forEach 有效地内置于：

a = ['a','b','c']
for el,i in a
    alert "Element #{el} is at index #{i}"

Answer 2

枚举：

arr.forEach (x, i) ->
    ... use x and i ...

zip / zipWith（我从 Haskell 学到了这些；我认为它们在 Python 中的意思是相同的？）：

zip = (arr1, arr2) ->
  basic_zip = (el1, el2) -> [el1, el2]
  zipWith basic_zip, arr1, arr2

zipWith = (func, arr1, arr2) ->
  min = Math.min arr1.length, arr2.length
  ret = []

  for i in [0...min]
    ret.push func(arr1[i], arr2[i])

  ret

一些示例（经过测试）：

zip([1, 2, 3], [4, 5, 6])          # => [[1, 4], [2, 5], [3, 6]]

add = (el1, el2) -> el1 + el2
zipWith(add, [1, 2, 3], [4, 5, 6]) # => [5, 7, 9]

---

更新：重新实现 Haskell 风格，只是为了好玩。如果没有模式匹配，就不那么酷了，但是哦，好吧..

zipWith = (func, arr1, arr2) ->
  return [] if arr1.length is 0 or arr2.length is 0

  el1 = arr1.shift()
  el2 = arr2.shift()

  ret_arr = zipWith func, arr1, arr2
  ret_arr.unshift func(el1, el2)

  ret_arr

哦，伙计，这很有趣。所以需要更多这样的问题：D

Gist for zip 和 zipWith

Answer 3

对于压缩和其他此类实用函数，Underscore.js 几乎是标准库 - 而且它恰好是由 Jeremy 创建的Ashkenas，CoffeeScript 背后的人。有了它，您可以

for elems in _.zip(arr1, arr2)
  x = elems[0]; y = elems[1]
  ...

编写您的 zip 示例，或者更好

for [x, y] in _.zip(arr1, arr2)
  ...

使用模式匹配 。但请注意，_.zip 使用 arr1 和 arr2 的最大长度，而不是最小长度；因此，如果您不想处理未定义的值，则应首先截断较长的数组。

还有一个 Underscore 的 CoffeeScript 实现，Underscore.coffee，这是一个很好的地方如果您想知道如何在 CoffeeScript 中实现特定循环，请查看。

Answer 4

CoffeeScript Cookbook 列出了 zip 函数的一个很好的实现：

# Usage: zip(arr1, arr2, arr3, ...)
zip = () ->
  lengthArray = (arr.length for arr in arguments)
  length = Math.min(lengthArray...)
  for i in [0...length]
    arr[i] for arr in arguments

zip([0, 1, 2, 3], [0, -1, -2, -3])
# => [[0, 0], [1, -1], [2, -2], [3, -3]]

http://coffeescriptcookbook.com/chapters/arrays/zip-function

Answer 5

不要忘记 CoffeeScript 只是 ECMAScript 的替代语法。至少对于您的第一个示例，有一个非常好的 ECMAscript 函数（Array.prototype。 forEach），它已经完成了您想要的操作：

arr = ["a", "b", "c"]

arr.forEach (el, i) ->
  alert "Element #{el} is at index #{i}"

不幸的是，没有 Array.prototype.zip 或 Array.prototype.zipWith。这似乎是一个相当大的遗漏，特别是考虑到同时存在 reduce 和 reduceRight，后者是许多其他语言所没有的。我的猜测是，这是一个简单的疏忽，我们将在该语言的某些未来版本中看到 zip。

Answer 6

对于 zip，请尝试以下方法：

zip = (x...) ->
  (y[i] for y in x for i in [0...Math.min (y.length for y in x)...])

如果您希望一直压缩到最后，请使用 Math.max()。