添加列表的最后两个元素

Question

在 Mathematica 中，获取列表

{r1, r2, r3, ..., rn, a, b}

并返回

{r1, r2, r3, ..., rn, a + b}

或更一般的

{r1, r2, r3, ..., rn, f[a, b]}

某些函数 f 的最简洁方法是什么？

Answer 1

lst = {a[1], a[2], a[3], a[4], a[5], a[6], a[7], a, b}; 
lst /. {a___, b_, c_} -> {a, f[b, c]}

 ==> {a[1], a[2], a[3], a[4], a[5], a[6], a[7], f[a, b]}

或（丑陋）：

Append[Take[lst, {1, -3}], f @@ lst[[{-2, -1}]]]

Answer 2

如果性能不是一个大问题（列表未打包等），我会使用规则：

 lst = {a, b, c, d, e}

 In[13]:= Replace[lst, {left__, ntl_, l_} :> {left, f[ntl, l]}, {0}]

 Out[13]= {a, b, c, f[d, e]}

Answer 3

如果我没有第二次猜到西蒙，我就会第一个回答。坚果。无论如何，这是我迟到的回复。

combineLast =
  Module[{x = #},
    x[[-2]] = #2 @@ x[[-2 ;;]];
    Most[x]
  ] &;

比较：

leoCL[lst_, f_] := Replace[lst, {left__, ntl_, l_} :> {left, f[ntl, l]}, {0}]

a = RandomInteger[1*^9, 5000];

Do[combineLast[a, Plus], {5000}] // Timing
Do[leoCL[a, Plus], {5000}] // Timing

{0.078, Null}

{1.844, Null}

Answer 4

假设定义了 'list'：

Remove[list];
list = {r1, r2, r2, r4, r5, a, b};

将 'list' 重新设置为 {r1, r2, r3, r4, r5, a}，并将 [[-1]] 替换为 'list' 中最后两个元素的总和。

list = ReplacePart[Drop[list, -1], -1 -> Plus @@ list[[-2 ;; -1]]]

谢谢你问这个，顺便说一句。 :)

Answer 5

这是我的看法：

addLastTwo = Function[Append[Drop[#, -2], Total[Take[#, -2]]]];

In[225]:= addLastTwo[{r1, r2, r3, r4, r5}]

Out[225]= {r1, r2, r3, r4 + r5}

这比 Mr.Wizard 的解决方案稍快一些，尽管不太通用：

In[226]:= Do[addLastTwo@a, {10000}] // Timing

Out[226]= {0.25, Null}

In[227]:= Do[combineLast[a, Plus], {10000}] // Timing

Out[227]= {0.39, Null}