具有多个相同元素的列表的排列 Prolog

Question

的语言的任何误用

大家好，请原谅我创建 myPermutation(L1,L2) 所需 。给定一个列表 L1 （其中包含许多连续出现的元素），返回一个列表 L2，该列表按 L1 排序，不存在两个相同的连续元素）

示例：给定列表 L1[1,1,1, 1,1,2,2,3,3,4,4,5,5] L2 应为 [1,2,1,5,1,3,1,4,1,2,3,5,4] 我尝试过随机排列并检查每个排列的一致性，但速度非常慢（L1 大约 24 个 cpu，具有超过 12 个元素）

唯一可能的解决方案是进行一致的排列，而不是检查一个排列 但我该怎么做呢？

即使使用标准序言也可能可以完成，但由于我对逻辑编程的理解很差，所以我无法理解它，

谢谢：D

Answer 1

您可以通过检查列表来构建此类排列。

myPermutation([], []).
myPermutation(L, [H|P]):-
  select(H, L, NL), % Select one item from the list
  myPermutation(NL, H, P).

myPermutation([], _, []).
myPermutation(L, H, [I|P]):-
  select(I, L, NL), % Select another item
  I \= H, % Enforce restriction of no duplicate consecutive items
  myPermutation(NL, I, P).

回溯时，此代码将给出所有有效的排列。我将留给您一个练习，一种丢弃重复排列的方法。

Answer 2

您可以使用 dif/2 快速完成此操作，它限制两个变量具有不同的值，而无需事先知道这些值：

?- dif(X,Y).
dif(X, Y).

?- dif(X,Y), X=1.
X = 1,
dif(1, Y).

?- dif(X,Y), X=1, Y=1.
false.

使用它，您可以创建一个谓词来约束列表，使得没有两个元素是相同：

conseq_dif([]).
conseq_dif([_]).
conseq_dif([X,Y|Xs]) :-
    dif(X,Y),
    conseq_dif([Y|Xs]).

现在找到您想要的约束排列：

constrained_perm(Lst,Prm) :-
    length(Lst,N),
    length(Prm,N),           % make list of N unbound variables
    conseq_dif(Prm),
    permutation(Lst,Prm).    % "ordinary" (library) permutation finding

我不确定 dif/2 是否是标准 Prolog，但主要实现都有它。

Answer 3

我们基于 same_length/2,
list_permuted/2，dif 和 mapadj/2：

my_perm(Xs,Ys) :-
   same_length(Xs,Ys),
   mapadj(dif,Ys),
   list_permuted(Xs,Ys).

多功能的 meta-predicate mapadj/2 可以这样定义this：

:- meta_predicate mapadj(2,?), list_mapadj(?,2), list_prev_mapadj(?,?,2).
mapadj(P_2,Xs) :-
   list_mapadj(Xs,P_2).

list_mapadj([],_).
list_mapadj([A|As],P_2) :-
   list_prev_mapadj(As,A,P_2).

list_prev_mapadj([],_,_).
list_prev_mapadj([A1|As],A0,P_2) :-
   call(P_2,A0,A1),
   list_prev_mapadj(As,A1,P_2).

---

这是 OP 给出的示例查询^1,2。

我们使用 call_time/2 来测量运行时间（以毫秒为单位）T_ms.

?- call_time(my_perm([1,1,1,1,1,2,2,3,3,4,4,5,5],[1,2,1,5,1,3,1,4,1,2,3,5,4]),T_ms).
T_ms = 0.

我们需要多长时间才能找到前几个解决方案？

?- call_time(my_perm([1,2,1,5,1,3,1,4,1,2,3,5,4],Xs),T_ms).
  T_ms =  0, Xs = [1,2,1,5,1,3,1,4,1,2,3,5,4]
; T_ms =  0, Xs = [1,2,1,5,1,3,1,4,1,2,3,4,5]
; T_ms = 10, Xs = [1,2,1,5,1,3,1,4,1,2,5,3,4]
; T_ms = 10, Xs = [1,2,1,5,1,3,1,4,1,2,4,3,5]
; T_ms = 10, Xs = [1,2,1,5,1,3,1,4,1,2,5,4,3]
; T_ms = 10, Xs = [1,2,1,5,1,3,1,4,1,2,4,5,3]
; T_ms = 10, Xs = [1,2,1,5,1,3,1,4,1,3,2,5,4]
; T_ms = 20, Xs = [1,2,1,5,1,3,1,4,1,3,2,4,5]
; T_ms = 20, Xs = [1,2,1,5,1,3,1,4,1,5,2,3,4]
; T_ms = 20, Xs = [1,2,1,5,1,3,1,4,1,4,2,3,5]
; T_ms = 20, Xs = [1,2,1,5,1,3,1,4,1,5,2,4,3]
; T_ms = 20, Xs = [1,2,1,5,1,3,1,4,1,4,2,5,3]
; T_ms = 20, Xs = [1,2,1,5,1,3,1,4,1,3,5,2,4]
; T_ms = 20, Xs = [1,2,1,5,1,3,1,4,1,3,4,2,5]
; T_ms = 20, Xs = [1,2,1,5,1,3,1,4,1,5,3,2,4]
; T_ms = 20, Xs = [1,2,1,5,1,3,1,4,1,4,3,2,5]
; T_ms = 30, Xs = [1,2,1,5,1,3,1,4,1,5,4,2,3]
; T_ms = 30, Xs = [1,2,1,5,1,3,1,4,1,4,5,2,3]
...

请注意，T_ms 单调增长：它测量自第一次调用给定目标以来所花费的时间。

枚举所有解决方案需要多长时间？

?- call_time(\+((my_perm([1,1,1,1,1,2,2,3,3,4,4,5,5],_),false)),T_ms).
T_ms = 4030.

有多少种解决方案？

?- use_module(library(aggregate)),
   aggregate(count,Xs,my_perm([1,2,1,5,1,3,1,4,1,2,3,5,4],Xs),N).
N = 197664.

---

<sup>脚注 1：使用 SICStus Prolog 版本 4.3.2 (x86_64-linux-glibc2.12)。

脚注 2：为了可读性，对 Prolog 处理器给出的答案序列进行了调整。</sup>