VBA - 从属性获取返回数组

Question

如果数组是通过引用返回的，为什么下面的方法不起作用：

'Class1 class module
Private v() As Double
Public Property Get Vec() As Double()
    Vec = v()
End Property
Private Sub Class_Initialize()
    ReDim v(0 To 3)
End Sub
' end class module

Sub Test1()
    Dim c As Class1
    Set c = New Class1
    Debug.Print c.Vec()(1) ' prints 0 as expected
    c.Vec()(1) = 5.6
    Debug.Print c.Vec()(1) ' still prints 0
End Sub

Answer 1

你没有出租房产。此外，get 属性返回整个数组，而不仅仅是相关元素。将 Property Get 的返回类型从 Double() 更改为普通 Double。添加物业出租。请注意，它需要两个输入，但只传递一个输入。假定最后一个变量（在本例中为 MyValue）从 = 符号后面的内容获取其值。在 Test1() 早期的某个位置放置一个断点，并查看“局部变量”窗口中的值如何受到影响。比较原始代码与我的代码创建的变量：

'Class1 class module
Private v() As Double
Public Property Get Vec(index As Long) As Double
    Vec = v(index)
End Property
Public Property Let Vec(index As Long, MyValue As Double)
    v(index) = MyValue
End Property
Private Sub Class_Initialize()
    ReDim v(0 To 3)
End Sub
' end class module

'Begin module
Sub Test1()
    Dim c As Class1
    Set c = New Class1
    Debug.Print c.Vec(1) ' prints 0 as expected
    c.Vec(1) = 5.6
    Debug.Print c.Vec(1) ' prints 5.6
End Sub
'End module  

Answer 2

在 VBA 中，数组永远不会通过引用返回，除非它们是通过 ByRef 参数返回的。此外，每当您使用 = 将数组分配给变量时，您都会创建该数组的新副本，即使您将其分配给过程内的 ByRef 参数，因此您想要让这项工作成功，我几乎不走运。

一些替代方法是...

• 使用 VBA.Collection 而不是数组。
• 创建您自己的类，封装数组并公开用于间接访问和操作内部数组的过程。

Answer 3

我想建议另一种好方法，使用 Collection 和 static Property 来完成此操作，而无需使用类：

假设您希望将 xlCVError 枚举作为数组（或集合），例如在出现错误时循环遍历它并根据实际错误进行处理。

以下内容在访问时初始化一次：

'from https://stackoverflow.com/a/56646199/1915920
Static Property Get XlCVErrorColl() As Collection
    Dim c As Collection  'will be already initalized after 1st access
                         'because of "Static Property" above!
    Set XlCVErrorColl = c
    If Not c Is Nothing Then Exit Property

   'initialize once:

    Set c = New Collection
    c.Add XlCVError.xlErrDiv0
    c.Add XlCVError.xlErrNA
    c.Add XlCVError.xlErrName
    c.Add XlCVError.xlErrNull
    c.Add XlCVError.xlErrNum
    c.Add XlCVError.xlErrRef
    c.Add XlCVError.xlErrValue
    Set XlCVErrorColl = c
End Property

将其转换为数组或将其实现为数组很简单，但集合对我来说似乎更有用，其缺点是它们的元素不是隐式类型化/（编译时-）类型已检查。
因此，这将例如将其转换为 （只读）数组（具有其他答案/评论中提到的 in-mem-copy-disadvantage）：

'from https://stackoverflow.com/a/56646199/1915920
Static Property Get XlCVErrorArr() As XlCVError()
   Dim a() As XlCVError
   XlCVErrorArr = a
   If UBound( a ) > 0 Then Exit Property

   'initialize once:

   Dim c As Collection:  Set c = XlCVErrorColl
   ReDim a(c.Count)
   Dim i As Integer:  For i = 1 To c.Count 
       a(i) = c(i)
   Next i
   XlCVErrorArr = a
End Function

因此，将示例从 Clayton S的答案到使用一些数组的静态、可修改的模块属性，它将是：

'module (no class required)
'from https://stackoverflow.com/a/56646199/1915920

Private v() As Double

Static Property Get Vec(index As Long) As Double
    If UBound(v) < 3 Then  'initialize once:
      ReDim v(0 To 3)  'one could initialize it with anyting after here too
    end if

    Vec = v(index)
End Property

Public Property Let Vec(index As Long, MyValue As Double)
    v(index) = MyValue
End Property