提取嵌套的 try/finally 块

Question

如何将嵌套的 try/finally 块从例程“提取”到可重用实体中？假设我拥有

procedure DoSomething;
var
  Resource1: TSomeKindOfHandleOrReference1;
  Resource2: TSomeKindOfHandleOrReference2;
  Resource3: TSomeKindOfHandleOrReference3;
begin
  AcquireResource1;
  try
    AcquireResource2;
    try
      AcquireResource3;
      try
        // Use the resources
      finally
        ReleaseResource3;
      end;
    finally
      ReleaseResource2;
    end;
  finally
    ReleaseResource1;
  end;
end;

并想要类似的东西

TDoSomething = record // or class
strict private
  Resource1: TSomeKindOfHandleOrReference1;
  Resource2: TSomeKindOfHandleOrReference2;
  Resource3: TSomeKindOfHandleOrReference3;
public
  procedure Init; // or constructor
  procedure Done; // or destructor
  procedure UseResources;
end;

procedure DoSomething;
var
  Context: TDoSomething;
begin
  Context.Init;
  try
    Context.UseResources;
  finally
    Context.Done;
  end;
end;

，我希望它具有与嵌套原始版本相同的异常安全性。在 TDoSomething.Init 中对 ResourceN 变量进行零初始化并在 TDoSomething.Done 中执行一些 if Assigned(ResourceN) then 检查是否足够？

Answer 1

关于类的三件事使得这个习惯用法安全且简单：

1. 在构造函数的内存分配阶段（在真正的构造函数主体运行之前），类引用字段被初始化为 nil。
2. 当构造函数发生异常时，会自动调用析构函数。
3. 对空引用调用 Free 始终是安全的，因此您无需先检查 Assigned。

由于析构函数可以依赖所有字段都具有已知值，因此它可以安全地对所有内容调用Free，无论构造函数在崩溃之前走了多远。每个字段要么保存一个有效的对象引用，要么为零，无论哪种方式，释放它都是安全的。

constructor TDoSomething.Create;
begin
  Resource1 := AcquireResource1;
  Resource2 := AcquireResource2;
  Resource3 := AcquireResource3;
end;

destructor TDoSomething.Destroy;
begin
  Resource1.Free;
  Resource2.Free;
  Resource3.Free;
end;

使用它的方式与使用任何其他类的方式相同：

Context := TDoSomething.Create;
try
  Context.UseResources;
finally
  Context.Free;
end;

Answer 2

是的，您可以对零初始化的多个资源使用单个 try/finally/end 块。

另一种可能的解决方案可以在 Barry Kelly 博客

Answer 3

Delphi 源代码中使用了在finally 中对Assigned 进行测试的模式。您做了同样的事情，但我认为您应该移动 Context.Init 以捕获 Context.Init 中的异常。

procedure DoSomething;
var
  Context: TDoSomething;
begin
  try
    Context.Init;
    Context.UseResources;
  finally
    Context.Done;
  end;
end;

编辑 1 这是在没有 Context.Init 和 Context.Done 的情况下应该如何进行的操作。如果将所有 AquireResource 代码放在 try 之前，则在 AcquireResource2 中出现异常时，您将不会释放 Resource1

procedure DoSomething;
var
    Resource1: TSomeKindOfHandleOrReference1;
    Resource2: TSomeKindOfHandleOrReference2;
    Resource3: TSomeKindOfHandleOrReference3;
begin
    Resource1 := nil;
    Resource2 := nil;
    Resource3 := nil;
    try
        AcquireResource1;
        AcquireResource2;
        AcquireResource3;

        //Use the resources

    finally
        if assigned(Resource1) then ReleaseResource1;
        if assigned(Resource2) then ReleaseResource2;
        if assigned(Resource3) then ReleaseResource3;
    end;
end;