查找绘图的最终显示区域中的框架/轴的坐标

Question

如果我使用 Frame->True 进行绘图，有没有办法可以在图像的绝对坐标中找到框架角的坐标？我有 PlotRange 和 PlotRangePadding 的数值，但请注意，我不想以任何方式篡改实际绘图，只需找出 Mathematica 在完整显示区域中选择放置绘图的框架/轴的位置即可。

正如 Brett Champion 所指出的，我正在寻找坐标 {x,y} 使得 Scaled[{0,0}] == ImageScaled[{x,y}]。

[请注意，我编辑了这个问题，以消除对术语“缩放坐标”的令人困惑的误用。]

Answer 1

框架的角位于 Scaled[{0,0}] 和 Scaled[{1,1}] 处。

完整图形（包括标签）的角点位于 ImageScaled[{0,0}] 和 ImageScaled[{1,1}] 处。

它们之间的转换很困难，尽管理论上如果您知道 PlotRange 和 PlotRangePadding 的实际数字设置，则可以转换 Scaled 和用户（未缩放）坐标。

根据您的应用程序，您也许还可以使用 MousePosition，它也知道这些事情。

Rasterize（和 HTML 导出）还知道如何在位图/像素坐标系中查找注释的边界框：

In[33]:= Rasterize[
 Plot[Sin[x], {x, 0, 10}, Frame -> True, 
  Prolog -> {LightYellow, 
    Annotation[Rectangle[Scaled[{0, 0}], Scaled[{1, 1}]], "One", 
     "Region"]}], "Regions"]

Out[33]= {{"One", "Region"} -> {{22., 1.33573}, {358.9, 209.551}}}

以下是 dreeves 如何使用 Rasterize 技巧来创建一个函数来准确返回他正在寻找的内容（注意全局变量 imgsz 的假设，它提供了用于光栅化绘图的 ImageSize 选项——框架的坐标取决于该值）：

(* Returns the geometry of the frame of the plot: 
   {width, height, x offset, y offset, total width, total height}. *)
geom[p_Graphics] := Module[{q, x1, y1, x2, y2, xmax, ymax},
  q = Show[p, Prolog->{Annotation[Rectangle[Scaled[{0,0}], Scaled[{1,1}]], 
                                  "MAGIC00","MAGIC11"]}];
  {{x1,y1}, {x2,y2}} = Rasterize[q, "Regions", ImageSize->imgsz][[1,2]];
  {xmax,ymax} = Rasterize[p, "RasterSize", ImageSize->imgsz];
  {x2-x1, y2-y1, x1, y1, xmax, ymax}]

Answer 2

框架左上角的坐标始终为Scaled[{0,1}]。
框架右下角的坐标始终为Scaled[{1,0}]。

让我们在左上角和右下角放置大点：

Plot[Cos[x], {x, 0, 10}, Frame -> True, 
Epilog -> {PointSize[.08], Point[Scaled[{0, 1}]], Point[Scaled[{1, 0}]]} ]

当我单击图形（见下文）时，很明显，图框周围没有填充。

现在，启用 ImagePadding，让我们放置 Point在相同的角上：

Plot[Cos[x], {x, 0, 10}, Frame -> True,  
ImagePadding -> {{37, 15}, {20, 48}}, 
Epilog -> {PointSize[.08], Point[Scaled[{0, 1}]],  Point[Scaled[{1, 0}]]} ]

点位于图框的角上。
图框周围有ImagePadding。

编辑：基于 dreeves 对问题的澄清。

Plot[Cos[x], {x, 1, 9}, ImageSize -> 300, AspectRatio -> 1, 
Frame -> True, ImagePadding -> 30, 
FrameTicks -> {Range[9], Automatic}, 
Epilog -> {PointSize[.08], Point[Scaled[{0, 1}]], Point[Scaled[{1, 0}]]}]

我将绘图绘制为 300x300 以简化数字。
这是分析。

1. 文档指出ImagePadding“是在ImageSize中定义的”。
2. 上面显示的图像的宽度和高度均为 300 像素。
3. 框架周围有 30 像素的边距；这相当于宽度和高度的 10%。
4. 因此，框架角应该从原点开始位于 ImageScaled[{.1,.1}]、ImageScaled[{.9,.1}、>ImageScaled[{.9,.9}] & ImageScaled[{.1,.9}]。

计算其他 AspectRatio 和 ImageSize 的值很容易。

Answer 3

一种可能性是手动控制 ImagePadding：

Plot[Sin[x], {x, 0, 10}, Frame -> True, 
 ImagePadding -> {{30, 5}, {20, 5}}]

ImageTake[Rasterize[%], {5, -20}, {30, -5}]