如何在mathematica中显示循环内的绘图

Question

我想知道你是否有好方法在 mma 中显示循环内的绘图。通常，Plot函数的输出不会显示，例如下面的代码：

For[i = 1, i <= 10, i++, Plot[Sin[i*x] , {x, -Pi, Pi}]]

感谢您的帮助。

编辑

关于我的上一个问题，我已经有了 For循环，例如，像这样 For[i = 1, i <= 10, i++, Plot[Sin[i*x], {x, -Pi, Pi}]]。鉴于这一事实，我希望在 For 循环内有类似“按任意键继续...”的内容，然后每次按任意随机键时刷新绘图。有人可以给出完整的工作代码吗？

Answer 1

只需使用 Print:

For[i = 1, i <= 10, i++, Plot[Sin[i*x], {x, -Pi, Pi}] // Print]

或 Monitor:

Monitor[For[i = 1, i <= 10, i++, p = Plot[Sin[i*x], {x, -Pi, Pi}]; 
  Pause[0.5]], p]

（此处使用暂停是为了给一些时间来查看绘图；这里的循环非常快。如有必要，请删除）

编辑
根据请求，通过鼠标点击图表来控制的版本（按键需要图表具有焦点，因此您无论如何都需要点击）

Monitor[For[i = 1, i <= 10, , p = Plot[Sin[i*x], {x, -Pi, Pi}]], 
EventHandler[p, {"MouseDown" :> i++}]]

这是一种非常愚蠢的方法。循环不断地重绘绘图。所以，一个稍微（但仍然丑陋）的版本可能是：

s = True;
Monitor[
 For[i = 1, i <= 10, ,
  If[s,
   (* Put main loop body here*) 
   p = Plot[Sin[i*x], {x, -Pi, Pi}] 
   (* end of main body *) ;
   s = False (* prevents continuous re-evaluating main body *)
   ]
  ]
 , EventHandler[p, {"MouseDown" :> (i++; s = True)}]
 ]

Answer 2

只需返回绘图列表，而不是使用 For 循环：

Table[Plot[Sin[i*x], {x, -Pi, Pi}], {i, 1, 10}]

如果您希望将它们全部连接为一个图，Show[listOfPlots] 是一种方法：

Show[Table[Plot[Sin[i*x], {x, -Pi, Pi}], {i, 1, 10}]]

更新

这是使用Dynamic和EventHandler的一种简单方法：

DynamicModule[{i = 1},
 EventHandler[Dynamic[Plot[Sin[i*x], {x, -Pi, Pi}]],
  {"KeyDown" :> i++}
  ]

这是使用Animate制作的稍微更奇特的界面：

Animate[Plot[Sin[i*x], {x, -Pi, Pi}], {i, 1, 10, 1}, AnimationRunning -> False]

Answer 3

如果您确实想让用户在绘图之间按某个键，最简单的方法可能是

For[i = 1, i <= 10, i++, 
    If[!ChoiceDialog[Plot[Sin[i*x], {x, -Pi, Pi}], 
         WindowTitle -> "Plot #" <> ToString[i] 
                                 <> ":  Press OK or Enter to continue"],
    Abort[]]]