有没有办法同时禁用多个按钮？

Question

我有一个 vba 用户窗体，上面有 36 个按钮。当我的电子表格之一上的值达到特定数字时，我想禁用所有按钮。现在，每次单击按钮，我引用的电子表格上的数字就会增加一。当数量达到三个时，我想禁用所有按钮。

Answer 1

Dim oCtrl As Control
Dim oButton As CommandButton

For Each oCtrl In MyForm.Controls
    If oCtrl.Tag = "SomeValue" Then
        Set oButton = oCtrl
        oButton.Enabled = False
    End If
Next

Set oCtrl = Nothing
Set oButton = Nothing

如果您不想禁用其他按钮，解决方案是使用 Tag 属性。将您想要同时启用或禁用的所有按钮的 Tag 属性设置为相同的值。然后您可以检查该值并启用/禁用它们。另一种方法是将它们命名为相同的前缀或后缀，并在代码中进行检查。

添加

顺便说一句，Control 对象没有 Enabled 属性。因此，您必须将其“投射”到 CommandButton 才能禁用它。显然，Control 对象确实具有 Enabled 属性，但它不会在智能感知中显示。但是，您仍然应该尝试将 Control 转换为 CommandButton，以确保这就是您所拥有的。这是一个扩展版本：

Dim oCtrl As Control
Dim oButton As CommandButton

For Each oCtrl In MyForm.Controls
    If oCtrl.Tag = "SomeValue" Then
        On Error Resume Next
        Set oButton = oCtrl
        On Error GoTo 0

        If Not oButton Is Nothing Then
            oButton.Enabled = False
        End If
    End If
Next

Set oCtrl = Nothing
Set oButton = Nothing

Answer 2

将所有按钮放在一个 Frame 对象中，然后禁用整个框架。这也将禁用框架内的所有内容。

或者，根据您的最后一个问题，您可以使用以下代码：

Dim counter As Integer

Private Sub btn1_Click()
    CaptureImage (btn1.Name)
End Sub

Private Sub btn2_Click()
    CaptureImage (btn2.Name)
End Sub

Private Sub btn3_Click()
    CaptureImage (btn3.Name)
End Sub

Private Sub UserForm_Activate()
    counter = 1
End Sub

Private Sub CaptureImage(ByVal btnName As String)
    Controls("capture" & counter).Picture = Controls(btnName).Picture
    counter = counter + 1
    If counter > 3 Then
        DisableButtons
    End If
End Sub

Private Sub DisableButtons()
    Dim ctl As Control
    For Each ctl In UserForm1.Controls
        If Left(ctl.Name, 3) = "btn" Then
            ctl.Enabled = False
        End If
    Next
End Sub

理想情况下，您希望像托马斯建议的那样将 Control 对象强制转换为按钮。

Answer 3

@Mike：尝试 --

If Sheets("Sheet1").Range("A1").Value = 3 Then 
    UserForm1.CommandButton1.Enabled = True 
Else 
    UserForm1.CommandButton1.Enabled = False 
End If

（将 Sheet1、A1、UserForm1 和 CommandButton1 替换为适合您工作簿的正确值）