VB 中的空检查

Question

我想做的就是检查一个对象是否为空，但无论我做什么，如果它编译，它会抛出一个 NullReferenceException 只是试图检查！这就是我所做的：

    If ((Not (comp.Container Is Nothing)) And (Not (comp.Container.Components Is Nothing))) Then
        For i As Integer = 0 To comp.Container.Components.Count() - 1 Step 1
            fixUIIn(comp.Container.Components.Item(i), style)
        Next
    End If

    If ((Not IsDBNull(comp.Container)) And (Not IsDBNull(comp.Container.Components))) Then
        For i As Integer = 0 To comp.Container.Components.Count() - 1 Step 1
            fixUIIn(comp.Container.Components.Item(i), style)
        Next
    End If

    If ((Not IsNothing(comp.Container)) And (Not IsNothing(comp.Container.Components))) Then
        For i As Integer = 0 To comp.Container.Components.Count() - 1 Step 1
            fixUIIn(comp.Container.Components.Item(i), style)
        Next
    End If

    If ((Not (comp.Container Is DBNull.Value)) And (Not (comp.Container.Components Is DBNull.Value))) Then
        For i As Integer = 0 To comp.Container.Components.Count() Step 1
            fixUIIn(comp.Container.Components.Item(i), style)
        Next
    End If

我浏览了 VB 书籍，搜索了几个论坛，但所有应该起作用的东西都不起作用！很抱歉问这样一个补救性的问题，但我只是需要知道。

如您所知，调试器表示 null 对象是 comp.Container

Answer 1

将 And 更改为 AndAlso

标准 And 将测试这两个表达式。如果 comp.Container 为 Nothing，则第二个表达式将引发 NullReferenceException，因为您正在访问 null 对象的属性。

AndAlso 将短路逻辑评估。如果 comp.Container 为 Nothing，则不会计算第二个表达式。

Answer 2

您的代码比必要的更加混乱。

将 (Not (X Is Nothing)) 替换为 X IsNot Nothing 并省略外括号：

If comp.Container IsNot Nothing AndAlso comp.Container.Components IsNot Nothing Then
    For i As Integer = 0 To comp.Container.Components.Count() - 1
        fixUIIn(comp.Container.Components(i), style)
    Next
End If

更具可读性。 …另请注意，我已删除了多余的 Step 1 和可能多余的 .Item。

但是（正如评论中所指出的），基于索引的循环无论如何都已经过时了。除非绝对必要，否则不要使用它们。使用 For Each 代替：

If comp.Container IsNot Nothing AndAlso comp.Container.Components IsNot Nothing Then
    For Each component In comp.Container.Components
        fixUIIn(component, style)
    Next
End If