函数的函数

Question

比如说，我有一些函数f[a_,b_,c_]=a+b+c。现在我需要定义另一个函数g[f_,d_]=f+d，这里的f应该替换为f的定义代码>，结果为a+b+c+d。

我该怎么做？我尝试了 g[f_,d_]=f+d/.f->Definition[f]，但这不起作用。

Answer 1

只是一个旁注。

当两个函数共享相同的参数，或者第二个函数的参数隐含在第一个函数中时，整个事情就更有意义了。

例如：

f[x_] := 1 + 1/x;

g[h_, x_] := h[x]^x;

Limit[g[f, x], x -> +Infinity]  
-> E

或者类似的东西

f[x_] := EuclideanDistance[x, #] &

g[f_, x_] := If[f[2 x]@x < 3, x, 2 x]

g[f, 3]
->6

g[f,2]
->2

Answer 2

丹尼尔的答案是正确的 - 它回答了你应该问的问题！

但只是为了好玩，这里更接近您的问题实际提出的问题。

f[a_,b_,c_] := a + b + c

g[f_, d_] := Catch[Module[{dv},
  Check[dv = DownValues[f], Throw[$Failed], {DownValues::sym}];
  Switch[Length[dv],
         0, Print["No DownValues"]; $Failed,
         1, dv[[1, 2]] + d,
         _?(# > 1 &), Print["More than one DownValue - using the first!"]; 
                      dv[[1, 2]] + d,
         _, Print["huh?!"]; $Failed]]]

测试它：

In[3]:= g[f, d]
Out[3]= a + b + c + d

定义另一个函数：

ff[a_, b_, c_] := a b c

In[5]:= g[ff, d]
Out[5]= a b c + d

并给它第二个定义：

In[6]:= ff[a_, b_] := a + b
In[7]:= DownValues[ff]
Out[7]= {HoldPattern[ff[a_,b_,c_]] :> a b c, HoldPattern[ff[a_,b_]] :> a+b}

In[8]:= g[ff, d]
During evaluation of In[8]:= More than one DownValue - using the first!
Out[8]= a b c + d

当然，事实上您没有将任何参数传递给 g[f_,d_] 中的 f （在大多数情况下）会让这种事情变得毫无意义......

Answer 3

在定义中，

 f[a_, b_, c_] := a+b+c

将 a、b 和 c 视为函数调用中的第一个、第二个 和 第三个 参数，而不是符号 a、b 或 c。与 f := (#1 + #2 + #3)& 类似，对 f 本身（不带参数）的调用不会给出所需的结果。

也许您想做这样的事情：

f := a+b+c

现在，f 关联为 a、b 和 c，它们是全局符号，而不是函数参数。然后，

f+d

将给出a + b + c + d，您可以使用ReplaceAll（或/.）进行替换：

f + d /. a->2x

给出b +c+d+2x。 2 f 将给出 2 (a+b+c)，Sin[f] 将给出 Sin[a+b+c ]，fc 将给出 a+b 等...

Answer 4

我也发现很难辨别您的意图，但这是我的解释：

f[a_, b_, c_] := a + b + c
g[f_, d_] := f[##] + d &;

g[f, 3]

  (* Out=  f[##1] + 3 &     *)

%[q, r, s]

  (* Out=  3 + q + r + s    *)

g[f, 5][1, 2, 3]

  (* Out=  11    *)

这样，g[f, x] 返回一个将其参数传递给 f 的函数。

Answer 5

好吧，你的设置要求 g 是 a、b 和 c 的函数，因为你明确地使 fa 成为其函数。可以改为：

f[a_,b_,c_]=a+b+c;

g[f_,a_,b_,c_,d_] = f[a,b,c]+d

Out[2]= a + b + c + d

Daniel Lichtblau