XSLT换行问题

Question

我正在尝试使用 xslt 根据 xml 文件中的字段生成 html 输出。我根据 xml 中的祖父母-父母-孩子-孙子关系命名它们

例如：

<root>
  <node1>
      <node2>
         <node3>Data</node3>
      </node2>
  </node1>

我需要的是创建一个名为 node1__node2__node3 的文本框 到目前为止我所做的是这个

<input type="text" name="node1__
        node2__
        node3__"

，但我想要的是：

<input type="text" name="node1__node2__node3__"/>

所以它是没用的。我的 xslt 产生这个无用的输出是：

<xsl:template name="chooseNameID">
    <xsl:param name="currentNode"/><!-- in this case currentNode is node3 -->
    <xsl:variable name="fieldNames">
        <xsl:for-each select="$currentNode/ancestor::*">
                <xsl:value-of select="name(.)"/>__
        </xsl:for-each>
    </xsl:variable>

    <xsl:attribute name="name">
        <xsl:value-of select="$fieldNames"/>                            
    </xsl:attribute>

</xsl:template>

我猜问题出在 但我找不到任何解决方案。

谢谢

Answer 1

此转换：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node3">
    <xsl:variable name="vName">
     <xsl:for-each select=
      "ancestor-or-self::*[not(position()=last())]">
        <xsl:value-of select="name()"/>
        <xsl:if test="not(position()=last())">__</xsl:if>
     </xsl:for-each>
    </xsl:variable>

    <input type="text" name="{$vName}"/>
 </xsl:template>
</xsl:stylesheet>

应用于提供的 XML 文档时：

<root>
    <node1>
        <node2>
            <node3>Data</node3>
        </node2>
    </node1>
</root>

产生所需的正确结果：

<input type="text" name="node1__node2__node3"/>

请注意：使用 AVT（属性值模板）在短短一行内生成所需的输出。

Answer 2

不需要的空格（包括换行符）是循环中文本节点文字的一部分。

在样式表文档中，除了 xsl:text 内之外，纯空白文本节点都会被忽略。然而，与其他文本相邻的空白是该文本的一部分。

样式表中的文字空白可以使用xsl:text 进行管理。

    <!-- change this -->
    <xsl:for-each select="$currentNode/ancestor::*">
        <xsl:value-of select="name(.)"/>__
    </xsl:for-each>

    <!-- to this -->
    <xsl:for-each select="$currentNode/ancestor::*">
        <xsl:value-of select="name(.)"/>__<xsl:text/>
    </xsl:for-each>

    <!-- or this -->
    <xsl:for-each select="$currentNode/ancestor::*">
        <xsl:value-of select="name(.)"/>
        <xsl:text>__</xsl:text>
    </xsl:for-each>

Answer 3

像往常一样，提出问题后你会找到解决方案。

使用此 行更改 为我工作。