根据参数应用不同的 XSLT 模板

Question

我有什么？

我有一个 ASP.NET 项目，其中有一个定义了许多模板的 XSLT 文件。根据用户选择，一次仅使用一个模板来在网页上显示内容。它看起来像这样：

    <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
      <xsl:param name="TemplateName"></xsl:param>

      <xsl:template match="Title_Only">
          ...template Title_Only body...
      </xsl:template>

      <xsl:template match="Image_Only">
          ...template Image_Only body...
      </xsl:template>

      <xsl:template match="Title_And_Image">
          ...template Title_And_Image body...
      </xsl:template>
    </xsl:stylesheet>

我想要什么？

我想将模板名称 TemplateName 作为参数传递，并能够在数据上应用相应的模板。

有人可以告诉我如何实现这一目标吗？

Answer 1

您不能在 XSLT 1.0 的匹配模式中使用参数或变量的值。但是，您可以有条件地从单个模板应用模板，如下所示：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:param name="TemplateName"/>
    <xsl:template match="/">
        <xsl:apply templates select="something[some_condition=$TemplateName]"/>
    </xsl:template>
</xsl:stylesheet>

...然后只需设置模板以分别匹配每种类型的节点。模板将仅应用于与您的 select 表达式匹配的内容，该表达式基于参数。

有条件应用模板的示例

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:variable name="TemplateName" select="'Title_Only'" />
    <xsl:template match="/">
        <xsl:apply-templates select="test/val[@name=$TemplateName]" />
    </xsl:template>
    <xsl:template match="val">
        <xsl:value-of select="@name" />
    </xsl:template>
</xsl:stylesheet>

应用于此输入：

<test>
    <val name="Title_Only" />
    <val name="Image_Only" />
    <val name="Title_And_Image" />
</test>

生成：

Title_Only

...基于 $TemplateName 的值。 （请注意，此示例使用变量，但其思想是相同的。）

使用模式分离模板

如果您确实需要在每种情况下使用完全不同的模板，则可以使用模式。此样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:variable name="TemplateName" select="'Title_Only'" />
    <xsl:template match="/">
        <xsl:choose>
            <xsl:when test="$TemplateName='Title_Only'">
                <xsl:apply-templates select="test/val" mode="Title_Only" />
            </xsl:when>
            <xsl:when test="$TemplateName='Image_Only'">
                <xsl:apply-templates select="test/val" mode="Image_Only" />
            </xsl:when>
            <xsl:otherwise>
                <xsl:apply-templates select="test/val" mode="Title_And_Image" />
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
    <xsl:template match="val" mode="Title_Only">
        <xsl:value-of select="@title" />
    </xsl:template>
    <xsl:template match="val" mode="Image_Only">
        <xsl:value-of select="@img" />
    </xsl:template>
    <xsl:template match="val" mode="Title_And_Image">
        <xsl:value-of select="@title" />/
        <xsl:value-of select="@img" />
    </xsl:template>
</xsl:stylesheet>

应用于此源：

<test>
    <val title="some title" img="some image"/>
</test>

生成：

some title

根据参数的值使用所需的模板。

Answer 2

我想传递模板名称
TemplateName 作为参数并为
能够应用相应的模板
数据。

在 XSLT 1.0 和 XSLT 2.0 中，具有如下构造是非法的：

<xsl:call-template name="{$vTemplateName}"/>

虽然 XPath 3.0 (XSLT 3.0) 引入了函数项和 HOF（高阶函数），但可以在以前的版本中模拟 HOF XSLT。欲了解更多信息，请阅读FXSL主页上的文章。

这里是 FXSL 背后思想的简化示例：

<nums>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
</nums>

给定此示例 XML，我们有两个模板，一个生成所有 num 元素的总和，另一个生成它们的值级联。我们希望将所需的操作作为参数传递。

以下是如何执行此操作（请注意，源 XML 本身中没有任何内容告诉我们要使用哪个操作）：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:my">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:param name="pOp" select="'sum'"/>

 <my:ops>
  <op>sum</op>
  <op>concat</op>
 </my:ops>

 <xsl:variable name="vOps" select=
   "document('')/*/my:ops/*"/>

 <xsl:template match="/">
  <xsl:apply-templates select="$vOps[. = $pOp]">
   <xsl:with-param name="arg1" select="/*/*"/>
  </xsl:apply-templates>
 </xsl:template>

 <xsl:template match="op[.='sum']">
  <xsl:param name="arg1"/>
  <xsl:value-of select="sum($arg1)"/>
 </xsl:template>

 <xsl:template match="op[.='concat']">
  <xsl:param name="arg1"/>

  <xsl:for-each select="$arg1">
   <xsl:value-of select="."/>
  </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

当应用于上面的 XML 文档时，会生成所需的正确结果：< /strong>

55

当我们替换:

 <xsl:param name="pOp" select="'sum'"/>

为:

 <xsl:param name="pOp" select="'concat'"/>

并应用新的转换时，再次产生想要的正确结果:

01020304050607080910

请注意：

主（使用）模板可以且通常位于单独的 XSLT 样式表文件中，并将导入带有实现操作的模板的样式表。主模板不知道实现了哪些操作（并且不使用带有硬编码名称的 ）。

事实上，如果在导入的文件中添加或删除模板，则无需修改主（使用）模板。在这种编程风格中， 指令通常在生成主模板时选择尚未编写的执行模板。

Answer 3

参与 元素。