Perl 常量定义在专用包中

Question

我想为主 Perl 程序和其他包的所有常见声明设置一个专用包，而不是在每个标头中重复这些声明。我肯定弄错了，但无法弄清楚其背后的理由：

让我们假设：
- 我已在my_common_declarations.pm包中设置了我的通用数据。
- 我想在另一个包中使用这些数据，例如 my_perl_utils.pm。

#!/usr/bin/perl -w
package my_perl_utils;
use parent qw(Exporter);
our @EXPORT_OK = qw(f1 f2);
use my_common_declarations qw(debugme);
my %setup = &debugme;
my $DEBUGME = $setup{setup}{debugme};

# This generates this error : "Use of uninitialized value"
use constant true => $setup{setup}{'true'};
print "=" x25, "\nDEBUG true :\nimport = " . $setup{setup}{'true'} . "\nconstant = " , true , "\n", "=" x25, "\n"; 

sub f1{
# some rationals using the true or false constants
}

sub f2{
}

1;  

我无法成功地无错误地声明“true”常量。

我应该在主程序中仅导入一次公共声明包并在其中相应地声明常量，还是在需要该常量的每个包中重新声明它？

谢谢

Answer 1

您遇到的问题是脚本中运行时和编译时之间的交互。任何 use 声明都有一个隐式的 BEGIN {...} 块，这意味着它在编译时发生。对 %setup 的赋值发生在运行时，在声明常量之后。解决此问题的方法是声明变量，然后在 BEGIN 块中对其执行赋值。这样，该变量将在调用 useconstant... 时定义：

use my_common_declarations 'debugme';

my (%setup, $DEBUGME);  # declare variables with file scope

BEGIN {
    %setup   = debugme;                # assign to variables at compile time
    $DEBUGME = $setup{setup}{debugme};
}

use constant true => $setup{setup}{true}; # %setup is defined now

或者，由于您要导出一个返回散列的函数，为什么不让它返回一个散列引用，然后您可以将代码编写为：

use my_common_declarations 'debugme';

use constant true => debugme->{setup}{true};

在这种情况下，由于 debugme 是在编译时由第一个 use 语句导入的，因此它可以在 use 常量中使用... 行。

但是，既然您正在为公共声明声明一个包，为什么不将常量的定义移动到该包中，然后将诸如 true 之类的内容添加到该包的导出列表中呢？