嵌套let和lambda在Scheme中的排序

Question

Scheme 中的两个函数之间有什么区别，一个是这样定义的，

(define doSomething
    (lambda (x)
          (let (f (100))
               (f x))))

另一个是这样定义的？

(define doSomething
          (let (f (100))
            (lambda (x) 
               (f x)))) 

换句话说，如果 lambda 位于 let 或者之后？

Answer 1

你的代码不会运行。 :-)

我会假设你的意思是这些：

(lambda (x)
  (let ((f 100))
    (+ f x)))

并且

(let ((f 100))
  (lambda (x)
    (+ f x)))

在这两种情况下，你都会返回传入的参数加上 100。

然而，主要的区别（忽略关于 let 的技术细节只是lambda 的语法糖）是在第二个版本中，f 是一个自由变量。假设我们这样做：

(let ((f 100))
  (list (lambda (x)
          (+ f x))
        (lambda (x)
          (set! f x))))

这会返回一个包含两个 lambda 的列表：第一个与之前的一样，第二个允许您更改 f 的值。两个 lambda 访问相同的 f，因此运行 setter将影响稍后对第一个 lambda 的调用。

Answer 2

正如克里斯指出的那样，代码不会运行。因此，我将使用一个新示例来解释 let over lambda 习惯用法。

当您用 let 包围 lambda 形式时，如下所示：

 (let ((x 0))
   (lambda ()
     ; body
     ))

lambda 主体内的代码能够访问（包括修改）< code>x，即使在 let 结束并返回新函数之后也是如此。这是创建“闭包”的一个示例，一开始很难理解。

本质上，这意味着您可以创建具有某种“内部状态”的函数。您可以使用它来做一些事情，例如制作“累加器生成器”或制作计算它们被调用次数的函数，甚至模拟“对象”（内部状态+方法）。下面是一些人为的示例：

一个 double 函数，用于计算它被调用的次数：

(define double
  (let ((count 0)) ; closed over variable
    (lambda (x)
      (if (eq? x 'count)
          count
          (begin 
            (set! count (+ count 1)) ; incr the count variable introduced by let
            (+ x x))))))

> (double 1)
2
> (double 1)
2
> (double 1)
2
> (double 'count) ; ask the double function how many times it's been called
3
> 

这个示例确实是 Paul Graham 提供的 (http://www.paulgraham.com/accgen.html)

(define make-accumulator
  (lambda ()
    (let ((x 0))
      (lambda (i)
        (set! x (+ x i)) ; incr x by i
        x))))

> (define acc (make-accumulator))
> (acc 1)
1
> (acc 1)
2
> (acc 1)
3
> (acc 1)
4
> 

每次<使用 1 调用 code>acc 时，它返回的值不同。

有关“对象”的示例，请搜索“对象和闭包”或阅读 SICP 的相关部分：http://mitpress.mit.edu/sicp/full-text/book/book-ZH-20.html#%_sec_3.1

Answer 3

另外两张（优秀的）海报围绕但没有明确提及的一点是：在没有 set! 的情况下，两者之间没有区别，因此可能没有理由使用您的第二种形式。