在类的所有实例方法中隐式使用 Groovy Category

Question

我有简单的 Groovy 类别类，它将方法添加到 String 实例：

final class SampleCategory {

    static String withBraces(String self) {
        "($self)"
    }

}

我想在我的单元测试中使用此类别（例如）。它看起来像这样：

class MyTest {
    @Test
    void shouldDoThis() {
        use (SampleCategory) {
            assert 'this'.withBraces() == '(this)'
        }
    }

    @Test
    void shouldDoThat() {
        use (SampleCategory) {
            assert 'that'.withBraces() == '(that)'
        }
    }
}

但是，我想要实现的是能够指定类别 SampleCategory 在 MyTest 的每个实例方法的范围内使用，所以我不必在每个方法中指定 use(SampleCategory) { ... }。

是否可以？

Answer 1

您可以使用 mixin 将类别直接应用于 String 的元类。将 null 分配给元类以将其重置为常规默认值。例如：

@Before void setUp() { 
    String.mixin(SampleCategory)
}

@After void tearDown() {
    String.metaClass = null
}

@Test
void shouldDoThat() {
    assert 'that'.withBraces() == '(that)'
}

Answer 2

现在您可以选择使用扩展模块而不是类别：
http://mrhaki.blogspot.se/2013/01 /groovy-goodness-adding-extra-methods.html

从好的方面来说，Intellij 会识别扩展。我刚刚注意到它甚至不需要像链接所建议的那样是一个单独的模块，只需将 META-INF/services/org.codehaus.groovy.runtime.ExtensionModule 添加到项目中：

# File: src/main/resources/META-INF/services/org.codehaus.groovy.runtime.ExtensionModule
moduleName = module
moduleVersion = 1.0
extensionClasses = SampleExtension

扩展类几乎是像普通类别一样定义：

class SampleExtension {
    static String withBraces(String self) {
        "($self)"
    }
}

可以这样使用：

def "Sample extension"() {
    expect: 'this'.withBraces() == '(this)'
}

如果您使用 Spock，则可以在规范上使用 @Use 注释。这样做的缺点是 Intellij 无法识别它。