基本 Flash/AS3 扩展 Sprite。我缺少什么？

Question

我刚刚开始尝试学习 Actionscript 3。我目前正在使用 FlashDevelop 作为我的 IDE。虽然我可以用其他语言编写代码，但 AS3 对我来说还是很新的（Flash 也是如此）。

我创建了一个基本类：

package 
{
    import flash.display.Sprite;

    public class BouncingBox extends Sprite
    {
        public function BouncingBox() 
        {
            x = 10;
            y = 10;
            width = 100;
            height = 100;
            graphics.clear();
            graphics.beginFill(0xD4D4D4); // grey color
            graphics.drawRoundRect(0, 0, 100, 100, 10, 10); // x, y, width, height, ellipseW, ellipseH
            graphics.endFill();
        }
    }
}

然后，从我的 Main() 类中，我执行以下操作：

package 
{
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.text.TextField;

    public class Main extends Sprite 
    {
        var mySprite:BouncingBox;

        public function Main():void 
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);
        }

        private function init(e:Event = null):void 
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);
            // entry point
            mySprite = new BouncingBox();
            addChild(mySprite);         

            var t:TextField = new TextField();
            t.text = "Testing!";
            addChild(t);        
        }
    }
}

我期望发生的情况是文本出现在顶部（确实如此），并且 BouncingBox 的实例出现在 10, 10 处舞台（实际上没有）。

为了让这个精灵出现在舞台上，我错过了什么？

Answer 1

这。

width = 100;
height = 100;

当精灵为空时设置它，它会弄乱它的变换矩阵。当绘制矩形时，它会自己给精灵这个大小。如果您想稍后缩放，请设置宽度和高度。

Answer 2

直到附加到显示列表后，您的对象才真正初始化。
尝试添加以下代码。

package 
{
    import flash.display.Sprite;

    public class BouncingBox extends Sprite
    {
    public function BouncingBox() 
    {
         if (stage) init();
        else addEventListener(Event.ADDED_TO_STAGE, init);
    }

    private function init(e:Event = null):void 
    {
        x = 10;
        y = 10;
        //width = 100;
        //height = 100;
        graphics.clear();
        graphics.beginFill(0xD4D4D4); // grey color
        graphics.drawRoundRect(0, 0, 100, 100, 10, 10); // x, y, width, height, ellipseW, ellipseH
        graphics.endFill();
    }
    }
}

另外，您可以附加您的盒子，然后初始化其位置等。

mySprite = new BouncingBox();
addChild(mySprite); 
mySprite.x = mySprite.y = 10;

另外，请考虑@alxx 在他的答案中写的内容。