如何获取 SICP、Scheme、练习 2.78 等中的 put 和 get 函数

Question

我正在尝试在 SICP 中做练习 2.78，但 put 和 get 函数未知。我尝试过多种语言，比如相当大、racket、r5rs、mit-scheme、mzscheme等。我什至下载了SICP支持（http://www.neilvandyke.org/sicp-plt/），但没有成功。我怎样才能让这些功能发挥作用？

Answer 1

是的，我发现 SICP 有时因为这样的事情有点烦人。假设存在但实际不存在的函数使得尝试示例变得更加困难。我像这样编写了自己的 (get) 和 (put)（这是 GNU guile 中的）：

(define global-array '())

(define (make-entry k v) (list k v))
(define (key entry) (car entry))
(define (value entry) (cadr entry))

(define (put op type item)
  (define (put-helper k array)
    (cond ((null? array) (list(make-entry k item)))
          ((equal? (key (car array)) k) array)
          (else (cons (car array) (put-helper k (cdr array))))))
  (set! global-array (put-helper (list op type) global-array)))

(define (get op type)
  (define (get-helper k array)
    (cond ((null? array) #f)
          ((equal? (key (car array)) k) (value (car array)))
          (else (get-helper k (cdr array)))))
  (get-helper (list op type) global-array))

从本书后面的角度来看，这可能是一个幼稚的实现，但相当简单且工作正常。

Answer 2

伊莱·本德斯基。
这些功能可以使用内置 基本哈希表操作。这是我对 Eli 代码的修改版本，以便与 MIT-Scheme 版本 9.1.1 正常工作。

(define *op-table* (make-hash-table))

(define (put op type proc)
  (hash-table/put! *op-table* (list op type) proc))

(define (get op type)
  (hash-table/get *op-table* (list op type) '()))

更新：

我在一段时间后发现了上述代码的错误。空列表在Scheme的条件子句中被解释为true，因此正确的get实现应该如下：

(define (get op type)
  (hash-table/get *op-table* (list op type) #f))

Answer 3

如果您使用 Racket 编程语言，请使用这些：

(define *op-table* (make-hash))

(define (put op type proc)
  (hash-set! *op-table* (list op type) proc))

(define (get op type)
  (hash-ref *op-table* (list op type) '()))

Answer 4

在3.3.3表示表的创建本地表小节中，有一个实现。

Answer 5

mit-scheme 有一个可供您使用的内置全局表。

http://www.gnu .org/software/mit-scheme/documentation/mit-scheme-ref/The-Association-Table.html

只需定义 get 和 put 即可：

(define get 2d-get)
(define put 2d-put!)

Answer 6

@Shen Yang 提到的，第 366~367 页的 3.3.3 表示表部分有一个实现

(define operation-table (make-table)) 
(define get (operation-table 'lookup-proc)) 
(define put (operation-table 'insert-proc!))

正如 “make-table”定义为：

(define (make-table)
  (let ((local-table (list '*table*)))
    (define (lookup key-1 key-2)
      (let ((subtable
             (assoc key-1 (cdr local-table))))
        (if subtable
            (let ((record
                   (assoc key-2 (cdr subtable))))
              (if record (cdr record) false))
            false)))
    (define (insert! key-1 key-2 value)
      (let ((subtable
             (assoc key-1 (cdr local-table))))
        (if subtable
            (let ((record
                   (assoc key-2 (cdr subtable))))
              (if record
                  (set-cdr! record value)
                  (set-cdr! subtable
                            (cons (cons key-2 value)
                                  (cdr subtable)))))
            (set-cdr! local-table
                      (cons (list key-1 (cons key-2 value))
                            (cdr local-table)))))
      'ok)
    (define (dispatch m)
      (cond ((eq? m 'lookup-proc) lookup)
            ((eq? m 'insert-proc!) insert!)
            (else (error "Unknown operation: TABLE" m))))
    dispatch))