软件交易内存 - 合并性示例

Question

总是被提及的软件事务内存的主要优点之一是可组合性和模块化。不同的片段可以组合起来产生更大的组件。在基于锁的程序中，情况通常并非如此。

我正在寻找一个用实际代码来说明这一点的简单示例。我更喜欢 Clojure 中的示例，但 Haskell 也很好。如果示例还展示了一些无法轻松编写的基于锁的代码，那就加分了。

Answer 1

Java 中锁不组合的示例：

class Account{
  float balance;
  synchronized void deposit(float amt){
    balance += amt;
  }
  synchronized void withdraw(float amt){
    if(balance < amt)
      throw new OutOfMoneyError();
    balance -= amt;
  }
  synchronized void transfer(Account other, float amt){
    other.withdraw(amt);
    this.deposit(amt);
  }
}

因此，存款可以，取款可以，但转账不行：如果当 B 开始向 A 转账时 A 也开始向 B 转账，我们可能会出现死锁情况。

现在在 Haskell STM 中：

withdraw :: TVar Int -> Int -> STM ()
withdraw acc n = do bal <- readTVar acc
                    if bal < n then retry
                    writeTVar acc (bal-n)

deposit :: TVar Int -> Int -> STM ()
deposit acc n = do bal <- readTVar acc
                   writeTVar acc (bal+n)

transfer :: TVar Int -> TVar Int -> Int -> STM ()
transfer from to n = do withdraw from n
                        deposit to n

由于没有显式锁定，withdraw 和 deposit 自然地组合在 transfer 中。语义仍然确保如果提款失败，则整个传输失败。它还确保提款和存款将自动完成，因为类型系统确保您无法在原子之外调用转账。

atomically :: STM a -> IO a

这个例子来自于：
http://cseweb.ucsd.edu/classes/ wi11/cse230/static/lec-stm-2x2.pdf
改编自这篇论文，您可能想阅读：
http://research.microsoft.com/pubs/74063/beautiful.pdf

Answer 2

Ptival 示例到 Clojure 的翻译：

;; (def example-account (ref {:amount 100}))

(defn- transact [account f amount]
  (dosync (alter account update-in [:amount] f amount)))

(defn debit [account amount] (transact account - amount))
(defn credit [account amount] (transact account + amount))
(defn transfer [account-1 account-2 amount]
  (dosync
    (debit account-1 amount)
    (credit account-2 amount)))

所以 debit 和 credit 可以单独调用，并且像 Haskell 版本一样，交易嵌套，所以整个 传输操作是原子的，在提交冲突时会发生重试，您可以添加验证器以确保一致性等。

当然，语义是它们永远不会死锁。

Answer 3

这是一个 Clojure 示例：

假设您有一个银行账户向量（在现实生活中，该向量可能会更长......）：

(def accounts 
 [(ref 0) 
  (ref 10) 
  (ref 20) 
  (ref 30)])

(map deref accounts)
=> (0 10 20 30)

一个“转账”函数，可以在单笔交易中安全地在两个账户之间转账：

(defn transfer [src-account dest-account amount]
  (dosync
    (alter dest-account + amount)
    (alter src-account - amount)))

以及 如下所示：

(transfer (accounts 1) (accounts 0) 5)

(map deref accounts)
=> (5 5 20 30)

然后，您可以轻松地组合转账功能来创建更高级别的交易，例如从多个账户转账：

(defn transfer-from-all [src-accounts dest-account amount]
  (dosync
    (doseq [src src-accounts] 
      (transfer src dest-account amount))))

(transfer-from-all 
  [(accounts 0) (accounts 1) (accounts 2)] 
  (accounts 3) 
  5)

(map deref accounts)
=> (0 0 15 45)

请注意，所有多次转账都发生在单个组合交易中，即可以“组合”较小的交易交易。

使用锁来做到这一点很快就会变得复杂：假设需要单独锁定帐户，那么您需要做一些事情，例如建立关于锁获取顺序的协议，以避免死锁。正如乔恩正确指出的那样，在某些情况下，您可以通过对系统中的所有锁进行排序来做到这一点，但在大多数复杂的系统中这是不可行的。很容易犯难以察觉的错误。 STM 可以帮助您摆脱所有这些痛苦。

Answer 4

为了使 trprcolin 的示例更加惯用，我建议更改 transact 函数中的参数顺序，并使 借方 和 贷方 的定义更加紧凑。

(defn- transact [f account amount]
    ....  )

(def debit  (partial transact -))
(def credit (partial transact +))