MSIL 中的 [opt] 是什么意思？

Question

我发现 C# 4.0 中的“可选参数”功能非常有趣，因此我试图弄清楚它们是如何实现的。 所以我写了一个这样的方法：

private static void A(int a = 5) { }

编译它，然后在 IL DASM 中反编译它，这是 IL 代码：

.method private hidebysig static void  A([opt] int32 a) cil managed
{
  .param [1] = int32(0x00000005)
  // Code size       2 (0x2)
  .maxstack  8
  IL_0000:  nop
  IL_0001:  ret
} // end of method Program::A

并且它在元数据中包含以下内容：

(1) ParamToken : (08000002) Name : a flags: [可选] [ HasDefault] (00001010) Default: (I4) 5

于是我顺着线索写了一个这样的方法：

private static void B([Optional, DefaultParameterValue(78)]int b) { }

编译它并反编译它，我发现C#编译器为方法A和B生成了几乎相同的MSIL代码（除了名称）。

我们可以看到IL代码中没有属性的迹象，感觉不对，所以我写了一个这样的自定义属性：

[AttributeUsage(AttributeTargets.Parameter)]
public class MyTestAttribute : Attribute
{
}

然后在方法C中使用它，如下所示：

private static void C([MyTest]int c) { }

编译它，然后反编译它，哈哈，我发现了这个：

.method private hidebysig static void  C(int32 c) cil managed
{
  .param [1]
  .custom instance void ConsoleApplication1.MyTestAttribute::.ctor() = ( 01 00 00 00 ) 
  // Code size       2 (0x2)
  .maxstack  8
  IL_0000:  nop
  IL_0001:  ret
} // end of method Program::C

方法主体的第二行调用我的自定义属性的构造函数。

所以这引起了我的疑问：

1. [opt]是什么意思？我的意思是出现在方法 A 和 B 的参数前面的那个。
2. 为什么方法 C 调用应用于其参数的属性的构造函数，而方法 A 和 B 却没有调用？
3. 我似乎在元数据中找不到 DefaultParameterValueAttribute 的任何标志，但我可以找到OptionalAttribute 和 MyTestAttribute。这是为什么？我有什么遗漏的吗？

提前致谢。

Answer 1

C# 编译器不需要发出属性，因为 Param 元数据表已经可以通过 Flags 列描述可选值和默认值。

从 ECMA 335 中的 23.1.13 开始：

Flag            Value   Description
-----------------------------------------------------
In              0x0001  Parameter is [In]  
Out             0x0002  Parameter is [Out]  
Optional        0x0010  Parameter is optional  
HasDefault      0x1000  Parameter has a default value  
HasFieldMarshal 0x2000  Parameter has FieldMarshal  

参数可以具有指定它的标志值是可选的并具有默认值 (0x0010 | 0x1000)。具有默认值的参数将在常量元数据表中具有关联的标记。

Constant 元数据表有一个 Parent 列（它是相关的 Param 标记）和一个 Value 列（它是存储默认值的 Blob 堆的索引）。

因此，回答您的问题：

1. [opt] 表示 Param 令牌的 Flags 列设置了可选标志。
2. 正如我上面所说，我的猜测是 C# 编译器正在识别Optional/DefaultParameterValue 属性，并将它们简单地转换为参数标志。
3. 编辑：尽管参数使用了Optional 标志，但C# 编译器似乎正在为OptionalAttribute 发出未使用的TypeRef。不过，它不会发出 DefaultParameterValueAttribute 的 TypeRef。这可能是一个小的编译器错误，用于发出未使用的 TypeRefs/MemberRefs。

Answer 2

2 / 3;有一些属性被编译器解释为 IL 元数据，而不是真正的属性；看起来这里就是这种情况； [Serialized] 是另一个示例。默认值的数据如下： Default: (I4) 5 - 并非代码中的所有属性都会成为元数据中的属性（同样，我正在查看 [Serialized]这里）

---

关于[Serialized]（评论）的那个点；这是一个示例：

[Description("abc")]
class Foo { }

[Serializable]
class Bar { }

其核心 IL 是：

.class private auto ansi beforefieldinit Foo
    extends [mscorlib]System.Object
{
    .custom instance void [System]System.ComponentModel.DescriptionAttribute::.ctor(string) = { string('abc') }
    .method public hidebysig specialname rtspecialname instance void .ctor() cil managed
    {
    }

}
.class private auto ansi serializable beforefieldinit Bar
    extends [mscorlib]System.Object
{
    .method public hidebysig specialname rtspecialname instance void .ctor() cil managed
    {
    }

}

在 Foo 中（对于某些任意属性），我们得到：

.custom instance void [System]System.ComponentModel.DescriptionAttribute::.ctor(string) = { string('abc') }

但是这不适用于 [Serializable]；相反，它是类型的一部分：

.class private auto ansi serializable beforefieldinit Bar