需要有关使用动态 LINQ 库的 LINQ 查询的帮助

Question

请原谅我对此的无知。 我有这个 LINQ 查询： Dim ngBikersDataContext As New CarBikeWalkDataContext

bikersList = (From c In ngBikersDataContext.Reg_Bikers _
                        Order By c.L_Name _
                        Select New Bikers() With { _
                        .BikerID = c.BikerID, _
                        .F_Name = c.F_Name, _
                        .M_Name = c.M_Name, _
                        .L_Name = c.L_Name _
                        }).ToList()

如您所见，它是一个 LIST(OF )。以下是 bikersList 的定义：

Dim bikersList As List(Of Bikers) = TryCast(HttpContext.Current.Session("Bikers"), List(Of Bikers))

我需要能够排序，因此将使用动态 LINQ 库。因此，我将其添加到我的项目 Imported System.Linq.Dynamic 中并尝试使用此代码：

bikersList = (ngBikersDataContext.Reg_Bikers _
                    .OrderBy(SortExpression) _
                    .Select New Bikers() With { _
                        .BikerID = c.BikerID, _
                        .F_Name = c.F_Name, _
                        .M_Name = c.M_Name, _
                        .L_Name = c.L_Name _
                        }).ToList()

但现在我在下面看到蓝色的 scwiggly 线：

                    ngBikersDataContext.Reg_Bikers _
                    .OrderBy(SortExpression) _
                    .Select

并显示错误“重载解析失败，因为没有可访问的“选择”接受此数量的参数。 ” 在“NEW”上我收到一个错误“')'expected”。

有人请告诉我我做错了什么吗？ 谢谢

Answer 1

您将“扩展方法”语法与“查询语法”混淆了。

bikersList = (ngBikersDataContext.Reg_Bikers _
                .OrderBy(SortExpression) _
                .Select(Function(c) New Bikers() With { _
                    .BikerID = c.BikerID, _
                    .F_Name = c.F_Name, _
                    .M_Name = c.M_Name, _
                    .L_Name = c.L_Name _
                    })).ToList()

或者

bikersList = (From c in ngBikersDataContext.Reg_Bikers.OrderBy(SortExpression) _
              Select b = New Bikers() With { _
                    .BikerID = c.BikerID, _
                    .F_Name = c.F_Name, _
                    .M_Name = c.M_Name, _
                    .L_Name = c.L_Name _
                    }).ToList()