mathematica 中的列表索引

Question

令 S 为具有唯一元素的向量，并且 s 是其子集，也具有唯一元素；例如，S={1,2,3,4,5,6} 和 s={1,3,4,6}。现在给定另一个向量 c={7,8,9,7}，如何创建向量 C=[7,0,8,9,0,7] >，即，如果 S[[i]] 是 s 中的元素，则 C[[i]] 等于该元素在 c 中，其索引与 s 中的 S[[i]] 相同，否则为零。

我现在所拥有的看起来像

C=Array[0&,Length[S]];
j=1;
For[i=1,i<=Length[S],i++,If[MemberQ[s,S[[i]]],C[[i]]=c[[j]];j=j+1;]]; 

这可行，但来自 MATLAB 背景，我讨厌 for 循环，并且上述操作是 matlab 中的一个简单的索引操作。我确信有一种更聪明的方法可以实现这一点，即数学风格。有人有建议吗？

Answer 1

您要将 S 的元素替换为 c 中的元素或 0，因此：

ss = {1, 2, 3, 4, 5, 6}
s = {1, 3, 4, 6}
c = {7, 8, 9, 7}
r = Append[MapThread[Rule, {s, c}], Rule[_, 0]]
answer = Map[Replace[#, r] &, ss]

Answer 2

这比迄今为止发布的速度要快：

ss = {1, 2, 3, 4, 5, 6};   s = {1, 3, 4, 6};   c = {7, 8, 9, 7};

Replace[ss, Dispatch@Append[Thread[s -> c], _ -> 0], 1]

Answer 3

ss = {1, 2, 3, 4, 5, 6};
s = {1, 3, 4, 6};
c = {7, 8, 9, 7};
ss /. Join[MapThread[Rule, {s, c}],Thread[Rule[Complement[ss, s], 0]]]

编辑或：

answer = 0 ss; answer[[Position[ss, #, 1] & /@ s // Flatten]] = c;

Answer 4

这是一种方法。可能还有很多其他的。

s = {1, 2, 3, 4, 5, 6};
subS = {1, 3, 4, 6};
c = {7, 8, 9, 7};
d= s /. {x_Integer :> If[MemberQ[subS, x], c[[Position[subS, x][[1, 1]]]], 0]}

按照用户定义符号的惯例，我自始至终都使用小写变量名称。

Mathematica 使用花括号表示向量、列表、矩阵和表格。

Answer 5

如果 S 始终采用 {1, 2, ..., n} 形式（例如 Range[n]），则此使用 SparseArray 的解决方案大约是 @ 的两倍先生。向导在我对非常大的列表的测试中的答案：

Normal[SparseArray[Thread[s -> c], n, 0]]