将一个 xml 复制到另一个但更改节点属性和边属性

Question

我有一个格式为

<graph id=1>
  <nodes>
   <node id =2>
    <name value=node1/>
   </node>
   <node id =3>
    <name value=node3/>
   </node>
   <edges>
     <edge id=11 source=2 target=3/>
   </edges>
 </graph>

现在我想使用generate-id()更改节点id的xml，但这也应该在所有边上更改。例如，我将node1的id更改为“1a1”，因此它应该更改边的来源xml 中任意位置的“1a1”。 它应该对所有节点和边执行此操作。剩余的 xml 应该保持原样。

我的 xsl

<xsl:template match="@*|node()">
  <xsl:copy>
    <xsl:apply-templates select="@*|node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="@id[parent::node]">
  <xsl:attribute name="id">
  <xsl:value-of select="generate-id()"/>
    </xsl:attribute>
</xsl:template>

这会更改节点 id，但我想比较边缘源和目标并也更改它们。 边源和目标是一些节点 id 。

任何帮助将不胜感激。 谢谢

Answer 1

这个样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:key name="kElementById" match="*[@id]" use="@id"/>
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="@id">
        <xsl:attribute name="id">
            <xsl:value-of select="generate-id(..)"/>
        </xsl:attribute>
    </xsl:template>
    <xsl:template match="@source|@target">
        <xsl:attribute name="{name()}">
            <xsl:value-of select="generate-id(key('kElementById',.))"/>
        </xsl:attribute>
    </xsl:template>
</xsl:stylesheet>

有了这个格式良好的输入：

<graph id="1">
    <nodes>
        <node id ="2">
            <name value="node1"/>
        </node>
        <node id ="3">
            <name value="node3"/>
        </node>
        <edges>
            <edge id="11" source="2" target="3"/>
        </edges>
    </nodes>
</graph>

输出：

<graph id="IDAEQBBB">
    <nodes>
        <node id="IDAHQBBB">
            <name value="node1"></name>
        </node>
        <node id="IDALQBBB">
            <name value="node3"></name>
        </node>
        <edges>
            <edge id="IDAQQBBB" source="IDAHQBBB" target="IDALQBBB"></edge>
        </edges>
    </nodes>
</graph>

Answer 2

将此部分添加到您已有的 XSL 中。

<xsl:template match="@source[parent::edge]|@target[parent::edge]">
    <xsl:attribute name="{name()}">
        <xsl:value-of select="generate-id(//node[@id=current()]/@id)"/>
    </xsl:attribute>
</xsl:template>