主力：删除键值数组中的重复项

Question

我有一对大小相等的数组，我将它们称为键和值。

例如：

K: V
1: 99
1: 100
1: 100
1: 100
1: 103
2: 103
2: 105
3: 45
3: 67

键已排序，与每个键关联的值是 已排序。如何删除与每个键关联的重复项值 及其对应的键？

也就是说，我想将上面的内容压缩为：

1: 99
1: 100
1: 103
2: 103 <-- This should remain, since key is different
2: 105
3: 45
3: 67

我查看了 Thrust 中可用的流压缩函数，但是 找不到任何可以做到这一点的东西。这可能吗？ 推力？或者我是否需要编写自己的内核来标记重复项 模板然后将其移除？

Answer 1

键已排序，与每个键关联的值也已排序。因此，我们可以认为键值对已排序。如果 thrust::unique 可以将这两个向量视为单个向量，则它将直接处理此问题。这可以通过使用 zip_iterator 将每个位置的 2 个项目（键值）压缩到单个元组中来实现。

以下是如何就地实现此目的，并将键值向量修剪为仅唯一元素：

typedef thrust::device_vector< int >                IntVector;
typedef IntVector::iterator                         IntIterator;
typedef thrust::tuple< IntIterator, IntIterator >   IntIteratorTuple;
typedef thrust::zip_iterator< IntIteratorTuple >    ZipIterator;

IntVector keyVector;
IntVector valVector;

ZipIterator newEnd = thrust::unique( thrust::make_zip_iterator( thrust::make_tuple( keyVector.begin(), valVector.begin() ) ),
                                     thrust::make_zip_iterator( thrust::make_tuple( keyVector.end(), valVector.end() ) ) );

IntIteratorTuple endTuple = newEnd.get_iterator_tuple();

keyVector.erase( thrust::get<0>( endTuple ), keyVector.end() );
valVector.erase( thrust::get<1>( endTuple ), valVector.end() );

如果要压缩并生成单独的结果流，则需要为您的类型编写自己的二进制谓词，该谓词同时查看元组的元素。 thrust::zip_iterator 可用于从单独的数组形成虚拟元组迭代器。

一个完整的工作示例如下所示：

#include <iostream>
#include <thrust/tuple.h>
#include <thrust/functional.h>
#include <thrust/device_vector.h>
#include <thrust/iterator/zip_iterator.h>
#include <thrust/unique.h>

// Binary predicate for a tuple pair
typedef thrust::tuple<int, int> tuple_t;
struct tupleEqual
{
  __host__ __device__
    bool operator()(tuple_t x, tuple_t y)
    {
      return ( (x.get<0>()== y.get<0>()) && (x.get<1>() == y.get<1>()) );
    }
};

typedef thrust::device_vector<int>::iterator  intIterator;
typedef thrust::tuple<intIterator, intIterator> intIteratorTuple;
typedef thrust::zip_iterator<intIteratorTuple> zipIterator;
typedef thrust::device_vector<tuple_t>::iterator tupleIterator;

int main(void)
{
  thrust::device_vector<int> k(9), v(9);
  thrust::device_vector<tuple_t> kvcopy(9);

  k[0] = 1; k[1] = 1; k[2] = 1; 
  k[3] = 1; k[4] = 1; k[5] = 2;
  k[6] = 2; k[7] = 3; k[8] = 3;

  v[0] = 99;  v[1] = 100; v[2] = 100;
  v[3] = 100; v[4] = 103; v[5] = 103;
  v[6] = 105; v[7] = 45;  v[8] = 67;

  zipIterator kvBegin(thrust::make_tuple(k.begin(),v.begin()));
  zipIterator kvEnd(thrust::make_tuple(k.end(),v.end()));
  thrust::copy(kvBegin, kvEnd, kvcopy.begin());

  tupleIterator kvend = 
        thrust::unique(kvcopy.begin(), kvcopy.end(), tupleEqual());

  for(tupleIterator kvi = kvcopy.begin(); kvi != kvend; kvi++) {
    tuple_t r = *kvi;
    std::cout << r.get<0>() << "," << r.get<1>() << std::endl;
  }

  return 0;
}

Answer 2

只需做一点准备就可以进行流压缩。您基本上可以为每个键值对启动一个线程，检查前一个键值对是否相等，如果不相等：在与这些键值对大小相同的单独数组中设置一个标志（int = 1）。所有其他标志保持未设置状态 (int = 0)。然后根据flag数组对键值对进行流式压缩。