VBA - 动态创建公共类型变量？

Question

简单问一下，我的宏代码中包含所有这些静态设置的公共类型变量。这些应该代表 INI 文件的值。我希望的方式是代码都是动态的，基于 INI 文件中的内容。所以我不需要手动更新INI文件和后面的代码。

这是代码现在的样子。这是在它自己的模块内：

Public Type Fields
     Firstname as String
     Lastname as String
     Username as String
End Type

我正在考虑使用 ReadIniSection 读取 INI 文件的整个部分，但似乎不可能在公共类型中执行此操作>。我说得对吗？有可能以某种方式解决这个问题吗？

Answer 1

使用 Scripting.Dictionary 对象（设置对 Scripting.Runtime 库的引用）。

存储：

oDict.Add keyName, keyValue

读回：

oDict(keyName)

假设您有具有单个值的唯一键名称。

http://msdn.microsoft.com/en -us/library/x4k5wbx4%28v=vs.85%29.aspx

蒂姆

Answer 2

也可以（但可能不建议）以编程方式向模块添加代码。由于 VBA 不支持反射，因此这是该语言中唯一的“动态”编码类型。这在紧要关头很有用。

请参阅下面的片段。 addCode 子函数采用标准模块的名称、Type 的名称以及包含字段定义的数组。

它首先尝试删除现有的同名类型，然后添加新的类型定义。

Sub TestAdd()
    Dim FieldArray()

    FieldArray = Array( _
     "Firstname As String", _
     "Lastname As String", _
     "Username As String" _
    )


    AddCode "Module2", "Fields", FieldArray
End Sub

Sub AddCode(ModuleName As String, TypeName As String, FieldArray())
    Dim StartLine As Long, EndLine As Long, StartColumn As Long, EndColumn As Long, _
        CodeToInsert As String

    StartLine = 1: StartColumn = -1
    EndLine = -1: EndColumn = -1

    'Find the old type definition and remove it.
    With Application.VBE.ActiveVBProject.VBComponents(ModuleName).CodeModule

        'Search for the start of the type definition
        If .Find("Public Type " & TypeName, StartLine, StartColumn, EndLine, EndColumn, True) Then
            EndLine = EndLine + 1: StartColumn = -1: EndLine = -1: EndColumn = -1

            'Found the start, now find the end of the type definition
            If .Find("End Type", EndLine, StartColumn, EndLine, EndColumn, True) Then
                .DeleteLines StartLine, (EndLine - StartLine) + 1
            End If
        End If

        CodeToInsert = _
            "Public Type " & TypeName & vbCrLf & _
            Join(FieldArray, vbCrLf) & vbCrLf & _
            "End Type"

        .InsertLines StartLine, CodeToInsert
    End With

End Sub