Applescript：带有主题 pro 的新终端窗口

Question

我想创建一个脚本，打开一个主题为 pro 的新终端窗口。该脚本会是什么样子？我刚刚设法获得一个新窗口，但我想指定主题。

我为此创建了一个自动化服务，因为我想使用快捷方式。

我需要主题的属性或从中获取信息，以某种方式重建它。

---

这样效果很好：

将模式设置为 {"Basic", "Grass", "Novel", "Ocean", "Pro", "Red Sands"} 将 I 设置为从 1 到 6 的随机数

将主题设置为模式的第 I 项

但是如何获取当前主题？脚本完成后是否会丢失所有变量，或者是否以某种方式保存它？

Answer 1

这应该可以：

tell application "Terminal" to set current settings of (do script) to settings set "Pro"

不过不确定你的意思是什么：

我需要主题的属性或从中获取信息，以某种方式重建它。

Answer 2

我编写了这个 applescript，以便我可以轻松设置当前窗口的主题。它允许我设置一个特定的主题，从一组受祝福的主题中随机设置一个，或者从所有可用的主题中随机设置一个。

我在 .bashrc 中使用别名设置来轻松从命令行调用它。示例位于标题中。

-- StyleTerm.scpt
-- Sets theme of current terminal window/tab

-----------------------
-- Arguments
-----------------------
-- If a theme name is provided on the command line then set to that
-- Example
--   osascript StyleTerm.scpt Grass
--  
-- If multiple theme names are provided on command line then choose randomly among those
--    This allows for random behavior from within blessed set
-- Example
--   osascript StyleTerm.scpt Grass Basic Ocean "Red Sands"
--  
-- If no command line args are provided then choose randomly among all themes
-- Example
--   osascript StyleTerm.scpt
-----------------------

-----------------------
-- This is best utilized via aliases set up in shell config file
-- Examples from my .bashrc
--   # Theme specific aliases
--   alias grass='osascript ~/sbin/StyleTerm.scpt Grass'
--   alias basic='osascript ~/sbin/StyleTerm.scpt Basic'
--   # Random from blessed themes
--   alias btheme='osascript ~/sbin/StyleTerm.scpt Grass Basic Ocean "Red Sands"'
--   # Random themes
--   alias rtheme='osascript ~/sbin/StyleTerm.scpt'
-----------------------

on run argv
    tell application "Terminal"
        if (count argv) is 0 then
            -- Use random theme from all possible themes
            set newTheme to some settings set
            set current settings of selected tab of front window to newTheme
        else
            -- Use random theme from arguments 
            set newThemeName to some item argv
            set current settings of selected tab of front window to first settings set whose name is newThemeName
        end if
    end tell
end run