如何在Processing中获取屏幕坐标

Question

我正在使用处理来做一个项目。
我使用 draw 函数在素描板上画了一个草图（实际上是文本）。
我想获取文本每个单词的屏幕坐标来做一些其他有趣的事情。

我不知道我可以使用什么函数来检索、取回屏幕坐标。

任何人都可以帮忙解决这个问题吗？我会很感激你的帮助。

谢谢

Answer 1

希望我正确地理解了您的问题，下面的草图解释了如何实现解决方案。它的速度相当快，并且基本上依赖于手动单词定位。首先，我将整个文本分成单个单词；存储在 myWords 数组中。
在绘制循环中，我使用两个变量 - xPos 和 yPos - 来表示在屏幕上移动的假想光标。 if 子句检查当前单词是否会跳出草图区域（包括填充）：

        float xPosEnd = xPos + textWidth (myWords[i]);

如果是，则光标将跳到下一行的开头。

        if (xPosEnd > width - PADDING_X) {
            ...

现在间距依赖于鼠标，行高是固定的；但也很容易是动态的。您可以使用 xPos 和 yPos 变量来调整单词的位置。此外，xPosEnd 指示单词结束位置。正如我所说，这种方法速度相当快，也可以应用于角色级别。

手动文本定位脚本

public static final int FONT_SIZE = 20;
public static final float LINE_HEIGHT = FONT_SIZE * 1.3f;
public static final float PADDING_X = 25;
public static final float PADDING_Y = 15;

PFont font;
String myText;
String[] myWords;

float spacing = 5;

void setup () {
    size (480, 320);
    smooth ();

    font = createFont ("Arial", FONT_SIZE);
    textFont (font);

    myText = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, ";
    myText += "sed do eiusmod tempor incididunt ut labore et dolore magna aliqua. ";
    myText += "Ut enim ad minim veniam, quis nostrud exercitation ullamco laboris ";
    myText += "nisi ut aliquip ex ea commodo consequat.";

    myWords = myText.split (" ");
}

void draw () {

    background (0);

    float xPos = PADDING_X;
    float yPos = PADDING_Y + FONT_SIZE;

    // For every word in the text
    for (int i=0; i < myWords.length; i++) {

        // Calculate the expected end position of 
        // the current word in this line
        float xPosEnd = xPos + textWidth (myWords[i]);

        // Check if word is not to long 
        // for current screen bounds. If...
        if (xPosEnd > width - PADDING_X) {
            // Set the cursor to the beginning 
            // of the next line
            xPos = PADDING_X;
            yPos += LINE_HEIGHT;
        }

        // Display word at xPos-yPos
        text (myWords[i], xPos, yPos);

        // Move the cursor to the right for the 
        // next word in list
        xPos += textWidth (myWords[i]) + spacing;
    }
}

void mouseMoved () {
    spacing = map (mouseX, 0, width, 0, 40);
}

Answer 2

我可以使用什么函数来检索，
获取屏幕坐标

可能您正在寻找 screen 系统变量

描述
系统变量哪个
存储计算机的尺寸
屏幕。例如，如果当前
屏幕分辨率为1024x768，
screen.width 为 1024，screen.height
是 768。这些尺寸很有用
导出全屏时
应用程序。

---

示例程序

println ("Width:" + screen.width);
println ("Height:" + screen.height);

---

如需更多参考，请参阅语言 API

---

编辑

但我正在寻找方法
任何物体的坐标
画在素描板上。就像说如果
我有一些文字，我想知道
每个单词的起始和结束坐标
在正文中

你用什么方法来绘制文本？您将使用什么方法来制作文本动画？这取决于您用来查找坐标的方法。

如果您使用 text 方法，那么您提供的坐标为参数
例如：text(data, x, y)

如果您对文本进行动画处理以向右移动 5 个坐标，那么如果初始 x 坐标为 10，那么现在的 x 坐标将为 15。