与 CMAKE 链接的不同调试和发布库

Question

已经有一个线程，但并没有真正的帮助。我希望能够链接例如 Foo.lib 用于 Release 配置和 Foo_d.lib 用于 Debug 配置，我怎样才能做到这一点？ 如果我这样做：

target_link_libraries(MyEXE debug Foo_d)
target_link_libraries(MyEXE optimized Foo)

那么我的项目中有两个库用于调试配置？ 为什么没有发布选项？ （我正在使用 Visual Studio）。

Answer 1

target_link_libraries 需要一个列表，您不需要调用它两次。以下内容将起作用：

target_link_libraries(MyEXE debug Foo_d optimized Foo)

要回答另一个答案的评论中提出的问题，使用多个库的工作方式如下：

target_link_libraries(MyEXE
    debug Foo1_d optimized Foo1
    debug Foo2_d optimized Foo2)

请注意，如果您还将库构建为 CMake 项目的一部分，则无需指定 debug 或优化。 CMake 将为您选择正确的一个。

Answer 2

解决办法是：

SET(LINK_LIBRARY optimized Foo debug Foo_d)
target_link_libraries(MyEXE ${LINK_LIBRARY})

Answer 3

当您的库是项目的一部分或者您是项目的一部分时，就没有问题
使用 find_package 命令的配置模式导入它（请参阅文档 和示例）。
如果您无法修改第 3 方，那么它将生成 Config.cmake
（它可能不使用cmake工具或者你不想这样做）答案是模拟
这样的过程：

add_library(foo STATIC IMPORTED)
set_target_properties(foo PROPERTIES IMPORTED_LOCATION_DEBUG "/path/to/foo-d.lib")
set_target_properties(foo PROPERTIES IMPORTED_LOCATION_RELEASE "/path/to/foo.lib")

target_link_libraries(MyEXE foo)

请注意，与“调试”/“优化”功能不同，这种方法不仅限于调试/发布配置：

set_target_properties(foo PROPERTIES IMPORTED_LOCATION_MINSIZEREL "/path/to/foo-small.lib")

您还可以获得一些好东西，例如 INTERFACE_INCLUDE_DIRECTORIES：

set_target_properties(foo PROPERTIES INTERFACE_INCLUDE_DIRECTORIES "/path/to/foo/includes")

include_directories("/path/to/foo/includes") # this line not needed
target_link_libraries(MyEXE foo) # this command will add "/path/to/foo/includes" for you

和传递链接：

add_library(boo STATIC IMPORTED)
set_target_properties(boo PROPERTIES IMPORTED_LOCATION_DEBUG "/path/to/boo-d.lib")
set_target_properties(boo PROPERTIES IMPORTED_LOCATION_RELEASE "/path/to/boo.lib")

add_library(foo STATIC IMPORTED)
set_target_properties(foo PROPERTIES IMPORTED_LOCATION_DEBUG "/path/to/foo-d.lib")
set_target_properties(foo PROPERTIES IMPORTED_LOCATION_RELEASE "/path/to/foo.lib")

set_target_properties(foo PROPERTIES INTERFACE_LINK_LIBRARIES boo) # foo depends on boo

target_link_libraries(MyEXE foo) # boo will be linked automatically

当然，您可以使用常规的 cmake 命令，例如 find_library 和 find_package (... MODULE) 来估计位置而不是对其进行硬编码。

Answer 4

如果您的调试/发布库遵循某种模式，例如调试库上的 _d，您可以避免重复：

set (MY_LIBS
    foo
    bar
    baz
)

# Generate the list of files to link, per flavor.
set (LINK_LIST "")
foreach(x ${MY_LIBS})
    list (APPEND LINK_LIST debug ${x}_d optimized ${x})
endforeach()

target_link_libraries (mytarget
    commonlib1
    commonlib2
    ${LINK_LIST}
    )

这将生成

debug foo_d optimized foo
debug bar_d optimized bar

target_link_libraries 期望的相应行。

Answer 5

使用带有调试和优化参数的 target_link_libraries 的上部答案不适用于我的 cmake 3.14.6。
如果您遇到此错误，请尝试使用以下类型的代码：

set (FreeImage debug "FreeImageD" optimized "FreeImage")
set (Glog debug "glogd" optimized "glog")
set (EXTRA_LIBS ${FreeImage} ${Glog})
target_link_libraries(TexCompressor ${EXTRA_LIBS})

它只是将调试/优化对更改为变量定义。它适用于我的版本。