XSL为每个子节点重复父节点

Question

对于每个子节点，我想复制父节点，以便生成的 xml 仅包含父节点的一个子节点，其他节点相同。

这是一个示例输入

<a>
  <a1>header1</a1>
  <a2>header2</a2>
  <a3>
     <a31>
          <a311>line_1</a311>
          <a311>line_2</a311>
     </a31>
     <a32>5o$</a32>
     <a33>Add</a33>
  </a3>
  <a4>account_holder</a4>
</a>

我想要做的是 - 重复 a3 与节点 a311 出现的次数一样多。其余所有节点均保留

输出

<a>
   <a1>header1</a1>
   <a2>header2</a2>
   <a3>
      <a31>
          <a311>line_1</a311>
      </a31>
      <a32>5o$</a32>
      <a33>Add</a33>
   </a3>
   <a3>
      <a31>
          <a311>line_2</a311>
      </a31>
      <a32>5o$</a32>
      <a33>Add</a33>
    </a3>
    <a4>account_holder</a4>
</a>

Answer 1

使用“隧道参数”模式更语义化，此样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="@*|node()" name="identity">
        <xsl:param name="pCurrent"/>
        <xsl:copy>
            <xsl:apply-templates select="@*|node()">
                <xsl:with-param name="pCurrent" select="$pCurrent"/>
            </xsl:apply-templates>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="a3">
        <xsl:variable name="vCurrent" select="."/>
        <xsl:variable name="vDescendants" select=".//a311"/>
        <xsl:for-each select="$vDescendants|$vCurrent[not($vDescendants)]">
            <xsl:variable name="vDescendant" select="."/>
            <xsl:for-each select="$vCurrent">
                <xsl:call-template name="identity">
                    <xsl:with-param name="pCurrent" select="$vDescendant"/>
                </xsl:call-template>
            </xsl:for-each>
        </xsl:for-each>
    </xsl:template>
    <xsl:template match="a311">
        <xsl:param name="pCurrent"/>
        <xsl:if test="generate-id()=generate-id($pCurrent)">
            <xsl:call-template name="identity"/>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

输出：

<a>
    <a1>header1</a1>
    <a2>header2</a2>
    <a3>
        <a31>
            <a311>line_1</a311>
        </a31>
        <a32>5o
lt;/a32>
        <a33>Add</a33>
    </a3>
    <a3>
        <a31>
            <a311>line_2</a311>
        </a31>
        <a32>5o
lt;/a32>
        <a33>Add</a33>
    </a3>
    <a4>account_holder</a4>
</a>

编辑：处理无后代情况。

Answer 2

以下 (XSLT 1.0) 样式表产生所需的结果：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" />
        </xsl:copy>
    </xsl:template>
    <xsl:template match="a3">
        <xsl:apply-templates select="a31/a311" />
    </xsl:template>
    <xsl:template match="a311">
        <a3>
            <a31>
                <a311>
                    <xsl:value-of select="." />
                </a311>
            </a31>
            <xsl:apply-templates select="../../*[not(self::a31)]" />
        </a3>
    </xsl:template>
</xsl:stylesheet>

Answer 3

您没有指定 XSLT 版本。下面是一个 XSLT2 样式表，它将实现您想要的功能：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0">

  <xsl:output method="xml" indent="yes"/>
  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="a3" mode="#default">
    <xsl:apply-templates select="a31/a311"/>
  </xsl:template>

  <xsl:template match="a311">
    <xsl:apply-templates select="../.." mode="x">
      <xsl:with-param name="label" select="text()"/>
    </xsl:apply-templates>
  </xsl:template>

  <xsl:template match="a3" mode="x">
    <xsl:param name="label"/>
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <a31>
        <a311><xsl:value-of select="$label"/></a311>
      </a31>
      <xsl:apply-templates select="* except a31"/>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

它使用身份转换来传递“无趣”元素，同时捕获 节点并应用特殊处理。如果您需要 XSLT1 解决方案，只需

• 将 select="* except a31" 替换为 select="*[name() != 'a31']"
• 删除mode="#default"