XSLT - 用于显示目的的文档功能和匹配

Question

这是我的用户 xml:(users.xml)

<?xml version="1.0"?>
<a:class xmlns:a="a">
  <a:users>
   <a:user>User1</a:user>
   <a:userid>9901</a:userid>
  </a:users>
   <a:users>
   <a:user>User2</a:user>
   <a:userid>9902</a:userid>
  </a:users>
  <a:users>
   <a:user>User3</a:user>
   <a:userid>9903</a:userid>
  </a:users>  
   <a:users>
   <a:user>User4</a:user>
   <a:userid>9904</a:userid>
  </a:users> 
  <a:users>
   <a:user>User5</a:user>
   <a:userid>9905</a:userid>
  </a:users>   
</a:class>

这是我的sites.xml:

<?xml version="1.0"?>
<a:sites xmlns:a="a">
  <a:user>
   <a:hassite>true</a:hassite>
   <a:userid>9901</a:userid> 
  </a:user>
  <a:user>
   <a:hassite>false</a:hassite>
   <a:userid>9902</a:userid> 
  </a:user>
  <a:user>
   <a:hassite>true</a:hassite>
   <a:userid>9903</a:userid> 
  </a:user>
  <a:user>
   <a:hassite>false</a:hassite>
   <a:userid>9904</a:userid> 
  </a:user>
  <a:user>
   <a:hassite>false</a:hassite>
   <a:userid>9905</a:userid> 
  </a:user>  
</a:class>

我的 XSL 样式表:

<?xml version="1.0"?>
<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:a="a">

    <xsl:template match="/a:class/a:users">

            <xsl:value-of select="document('sites.xml')/a:sites/a:user/a:userid"/> 

    </xsl:template>

</xsl:stylesheet>

我想要做的是显示 users.xml 中的用户名和用户 ID，然后读取sites.xml，如果用户 ID位于 xml 中，并且 值等于 'false' 显示单词“active”。

谁能给我一些建议吗？

Answer 1

节点集比较就是为了这个目的：

<xsl:variable name="vSource2" select="document('sites.xml')">
<xsl:template match="/a:class/a:users">
    <xsl:if test="a:userid = $vSource2
                                /a:sites
                                   /a:user[a:hassite='true']
                                      /a:userid">
        <xsl:value-of select="a:userid"/>
    </xsl:if>
</xsl:template>

这样，您就可以使用模式

<xsl:template match="/a:class/a:users[
                        a:userid = document('sites.xml')
                                      /a:sites
                                         /a:user[a:hassite='true']
                                            /a:userid
                     ]">
    <xsl:value-of select="a:userid"/>
</xsl:template>

Answer 2

以下样式表：

<xsl:stylesheet  version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:a="a">
    <xsl:output method="text"/>
    <xsl:variable name="sites" select="document('sites.xml')"/>
    <xsl:template match="a:users">
        (<xsl:value-of select="a:user"/> / <xsl:value-of select="a:userid"/>  
        <xsl:if 
            test="$sites/a:sites/a:user[a:userid=current()/a:userid]/a:hassite='false'"> / active</xsl:if>)
    </xsl:template>
</xsl:stylesheet>

应用于 users.xml 时生成以下输出：

(User1 / 9901) 
(User2 / 9902 / active) 
(User3 / 9903) 
(User4 / 9904 / active) 
(User5 / 9905 / active) 

根据需要调整最终输出格式。