将表达式导出到 C，第 1 部分 [wolfram-mathematica]

Question

我在 Mathematica 中生成了几个表达式，我想将它们导出到外部 C 程序的源代码中。 “CForm”几乎达到了我想要的效果，除了求幂被表示为对 Power() 的调用。我的表达式仅涉及较小的幂，因此我更希望 C 中的表达式使用内联乘法而不是调用 Power()。

例如 CForm[2 hgt^2 k1inv^3 mx0 wid^2 + hgt^2 k1inv^3 wid^3] 产生

2*Power(hgt,2)*Power(k1inv, 3)*mx0*功率(宽度,2) + Power(hgt,2)*Power(k1inv,3)*Power(wid,3)

..而我想生成的是：

2*hgt*hgt*k1inv*k1inv*k1inv* mx0*宽度*宽度 + hgt*hgt*k1inv*k1inv*k1inv*wid*wid*wid

我最初尝试挑选表达式的内部 Power[..] 部分，并将其重新映射为乘法x_Symbol^y_Integer /; y＞ 1：> Fold[Times, 1, Table[#1, {#2}]] 被 mathematica 阻止，立即将我精心生成的子表达式 a*a*a 转换回 Power[a,3] ;-) 我知道它只是想提供帮助，但我不知道如何让它停止，在这种情况下......

正如我写的这个问题，它有我想到我可以捕获的输出CForm 转换为字符串，然后对其执行字符串模式匹配和操作，但这是一个好方法吗？我想我更喜欢将其作为 Mathematica 表达式来处理，因为我进行重新映射然后输出..？

Answer 1

对于当前的情况，您可以使用类似以下内容：

Clear[getCFormNoPowers];
getCFormNoPowers[expr_] :=
  Module[{times},      
   Apply[Function[code, Hold[CForm[code]], HoldAll],
     Hold[#] &[expr /. x_Symbol^y_Integer /; y > 1 :> 
         times @@ Table[x, {y}]] /. times -> Times]];

例如，

In[52]:= getCFormNoPowers[2 hgt^2 k1inv^3 mx0 wid^2+hgt^2 k1inv^3 wid^3]

Out[52]= Hold[2*mx0*(hgt*hgt)*(wid*wid)*(k1inv*k1inv*k1inv) + 
hgt*hgt*(k1inv*k1inv*k1inv)* (wid*wid*wid)]

将结果包装在 Hold 中，以防止其计算返回到 Power-s。您可以将其转换为
随时使用 ToString[HoldForm@@result] 之类的字符串。或者你可以进一步操纵。

编辑：

作为替代方案，您可以这样做：

Clear[getCFormNoPowers];
getCFormNoPowers[expr_] :=
 Block[{Times},
   SetAttributes[Times, {Flat, OneIdentity}];
   Apply[Function[code, Hold[CForm[code]], HoldAll],
   Hold[#] &[expr /. x_Symbol^y_Integer /; y > 1 :> Times @@ Table[x, {y}]]]];

这也将保留术语的原始顺序，并删除不必要的括号，因此这似乎与您的规格完全一致。

一般来说，您可能想看看版本 8 的新“符号 C 生成”功能。将代码映射到符号 C 表达式可能是一种更可靠的方法。这样，您就不必一直担心评估，并且最终可以使用新功能生成整个 C 程序。

编辑2：

为了说明如何使用SymbolicC解决问题：

Needs["SymbolicC`"];

Clear[getCFormNoPowersSymC];
getCFormNoPowersSymC[expr_] :=
  Block[{Times},
   SetAttributes[Times, {Flat, Orderless}];
   ToCCodeString[
     expr /. x_Symbol^y_Integer /; y > 1 :> Times @@ Table[x, {y}] //.     
       HoldPattern[(op : (Times | Plus))[args__]] :>  COperator[op, {args}]]];

In[53]:= getCFormNoPowersSymC[2 hgt^2 k1inv^3 mx0 wid^2+hgt^2 k1inv^3 wid^3]

Out[53]= 2 * hgt * hgt * k1inv * k1inv * k1inv * mx0 * wid * wid + 
    hgt * hgt * k1inv * k1inv * k1inv * wid * wid * wid

IMO这种方法有几个优点。也许两个主要的问题是可组合性（可以将这样的表达式嵌套在符号形式中，从较小的代码块构建更大的代码块），以及不需要太多考虑评估的事实（我不需要任何技巧） 按住此处）。