如何在groovy中检索嵌套属性

Question

我想知道在 Groovy 中检索嵌套属性的最佳方法是什么，采用给定的对象和任意“属性”字符串。我想要这样的事情：

someGroovyObject.getProperty("property1.property2")

我很难找到其他人想要这样做的例子，所以也许我不理解一些基本的 Groovy 概念。看来必须有一些优雅的方法来做到这一点。

作为参考，Wicket 中有一个功能正是我正在寻找的，称为 PropertyResolver： http://wicket.apache.org/apidocs/1.4/org/ apache/wicket/util/lang/PropertyResolver.html

任何提示将不胜感激！

Answer 1

我不知道 Groovy 是否有内置的方法来做到这一点，但这里有 2 个解决方案。在 Groovy 控制台 中运行此代码进行测试。

def getProperty(object, String property) {

  property.tokenize('.').inject object, {obj, prop ->       
    obj[prop]
  }  
}

// Define some classes to use in the test
class Name {
  String first
  String second
}

class Person {
  Name name
}

// Create an object to use in the test
Person person = new Person(name: new Name(first: 'Joe', second: 'Bloggs'))

// Run the test
assert 'Joe' == getProperty(person, 'name.first')

/////////////////////////////////////////
// Alternative Implementation
/////////////////////////////////////////
def evalProperty(object, String property) {
  Eval.x(object, 'x.' + property)
}

// Test the alternative implementation
assert 'Bloggs' == evalProperty(person, 'name.second')

Answer 2

Groovy Beans 让您可以直接访问字段。您不必定义 getter/setter 方法。它们是为您生成的。每当您访问 bean 属性时，都会在内部调用 getter/setter 方法。您可以使用 .@ 运算符来绕过此行为。请参阅以下示例：

class Person {
    String name
    Address address
    List<Account> accounts = []
}

class Address {
    String street
    Integer zip
}

class Account {
    String bankName
    Long balance
}

def person = new Person(name: 'Richardson Heights', address: new Address(street: 'Baker Street', zip: 22222)) 
person.accounts << new Account(bankName: 'BOA', balance: 450)
person.accounts << new Account(bankName: 'CitiBank', balance: 300)

如果您不处理集合，则只需调用要访问的字段即可。

assert 'Richardson Heights' == person.name
assert 'Baker Street' == person.address.street
assert 22222 == person.address.zip

如果要访问集合中的字段，则必须选择该元素：

assert 'BOA' == person.accounts[0].bankName
assert 300 == person.accounts[1].balance​​​​​​​​​

Answer 3

您还可以使用 propertyMissing。这就是您可能所说的 Groovy 的内置方法。

在您的类中声明这一点：

def propertyMissing(String name) {
    if (name.contains(".")) {
        def (String propertyname, String subproperty) = name.tokenize(".")
        if (this.hasProperty(propertyname) && this."$propertyname".hasProperty(subproperty)) {
            return this."$propertyname"."$subproperty"
        }
    }
}

然后根据需要引用您的属性：

def properties = "property1.property2"
assert someGroovyObject."$properties" == someValue

这是自动递归的，您不必显式调用方法。这只是一个 getter，但您也可以使用参数定义第二个版本来创建 setter。

缺点是，据我所知，您只能定义一个版本的 propertyMissing，因此您必须决定动态路径导航是否是您想要使用它的用途。

Answer 4

请参阅

https://stackoverflow.com/a/15632027/2015517

它使用 ${} 语法，可以用作一部分GString 的