f# 运行总计序列

Question

好吧，这看起来应该很容易，但我就是不明白。如果我有一个数字序列，如何生成由运行总计组成的新序列？例如，对于序列 [1;2;3;4]，我想将其映射到 [1;3;6;10]。以适当的功能方式。

Answer 1

使用 List.scan：

let runningTotal = List.scan (+) 0 >> List.tail

[1; 2; 3; 4]
|> runningTotal
|> printfn "%A"

基于Seq.scan的实现：

let runningTotal seq' = (Seq.head seq', Seq.skip 1 seq') ||> Seq.scan (+)

{ 1..4 }
|> runningTotal
|> printfn "%A"

Answer 2

另一种使用 Seq.scan 的变体（Seq.skip 1 去掉了前导零）：

> {1..4} |> Seq.scan (+) 0 |> Seq.skip 1;;
val it : seq<int> = seq [1; 3; 6; 10]

Answer 3

> Seq.scan (fun acc n -> acc + n) 0 [1;2;3;4];;
val it : seq<int> = seq [0; 1; 3; 6; ...]

使用列表：

> [1;2;3;4] |> List.scan (fun acc n -> acc + n) 0 |> List.tail;;
val it : int list = [1; 3; 6; 10]

编辑：序列的另一种方式：

let sum s = seq {
    let x = ref 0
    for i in s do
        x := !x + i
        yield !x
}

是的，有一个可变变量，但我发现它更具可读性（如果你想去掉前导 0）。

Answer 4

我认为值得分享如何使用 记录类型< /a> 如果这也是您来这里寻找的东西。

下面是一个虚构的示例，使用跑步者绕跑道跑一圈来演示这一概念。

type Split = double
type Lap = { Num : int; Split : Split }
type RunnerLap = { Lap : Lap; TotalTime : double }

let lap1 = { Num = 1; Split = 1.23 } 
let lap2 = { Num = 2; Split = 1.13 } 
let lap3 = { Num = 3; Split = 1.03 } 
let laps = [lap1;lap2;lap3]

let runnerLapsAccumulator =  
  Seq.scan 
    (fun rl l -> { rl with Lap = l; TotalTime = rl.TotalTime + l.Split }) // acumulator
    { Lap = { Num = 0; Split = 0.0 }; TotalTime = 0.0 } // initial state

let runnerLaps = laps |> runnerLapsAccumulator
printfn "%A" runnerLaps

Answer 5

不确定这是最好的方法，但它应该可以解决问题

  let input = [1; 2; 3; 4]
  let runningTotal = 
    (input, 0) 
    |> Seq.unfold (fun (list, total) ->
      match list with
      | [] -> 
        None
      | h::t -> 
        let total = total + h
        total, (t, total) |> Some)
    |> List.ofSeq