XML 文档到 XHTML 文档的 XSLT 转换

Question

这是我的模板：

<xsl:template name="rec">
  <xsl:for-each select="*">
    <div class="{local-name()}">
      <xsl:for-each select="@*">
        <xsl:attribute name="data-{local-name()}">
          <xsl:value-of select="."/>
        </xsl:attribute>
      </xsl:for-each>
      <xsl:value-of select="text()" />
      <xsl:call-template name="rec" />
    </div>
  </xsl:for-each>
</xsl:template>

给定一个像这样的文档：

<test>
  <item value="1">Item 1 Text</item>
  <item value="2">Item 2 Text</item>
</test>

上面的转换将把它变成：

<div class="test">
  <div class="item" data-value="1">Item 1 Text</div>
  <div class="item" data-value="2">Item 2 Text</div>
</div>

我遇到的问题是，这个转换没有正确尊重文本节点，而且我没有足够的 XSLT 背景来弄清楚如何修复它。问题是这样的：给定 xml，如下所示：

<para>This is a <emphasis>paragraph</emphasis> people!</para>

我想看到以下输出：

<div class="para">This is a <div class="emphasis">paragraph</div> people!</div>

问题是我没有得到这个 - 我得到了这个：

<div class="para">This is a <div class="emphasis">paragraph</div></div>

注意缺少的“人！”文本节点。如何修复上面的 XSLT 以提供我需要的输出？

Answer 1

一个问题是

  <xsl:value-of select="text()" />

仅选择第一个子文本节点的值并将其输出。

正确执行此操作的最简单方法可能是使用 而不是 。

然后，

  <xsl:for-each select="*">

和

  <xsl:value-of select="text()" />

您可以使用

  <xsl:apply-templates />

来将适当的模板按顺序应用于每个子元素和文本节点，而不是跳过任何模板。

这是一个完整的实现：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   version="1.0">

   <xsl:template match="*">
      <div class="{local-name()}">
         <xsl:for-each select="@*">
            <xsl:attribute name="data-{local-name()}">
               <xsl:value-of select="."/>
            </xsl:attribute>
         </xsl:for-each>
         <xsl:apply-templates />
      </div>
   </xsl:template>

</xsl:stylesheet>

请注意 ，它在没有显式 的情况下默认对上下文节点的所有子节点（包括文本节点）进行操作选择 属性。

默认模板用于文本节点。该模板只是将它们复制到输出中。

示例输入：

<test>
   <item value="1">Item 1 Text</item>
   <item value="2">Item 2 Text</item>
   <para>This is a <emphasis>paragraph</emphasis> people!</para>
</test>

产生所需的输出：

<div class="test">
   <div class="item" data-value="1">Item 1 Text</div>
   <div class="item" data-value="2">Item 2 Text</div>
   <div class="para">This is a <div class="emphasis">paragraph</div> people!</div>
</div>