定位器超出图形区域

Question

当我运行以下代码

pMin = {-3, -3};
pMax = {3, 3};
range = {pMin, pMax};
Manipulate[
 GraphicsGrid[
  {
   {Graphics[Locator[p], PlotRange -> range]},
   {Graphics[Line[{{0, 0}, p}]]}
   }, Frame -> All
  ],
 {{p, {1, 1}}, Locator}
]

我希望定位器控件位于第一个图形的范围内，但相反可以在整个 GraphicsGrid 区域中移动。我的代码有错误吗？

我也尝试

{{p, {1, 1}}, pMin, pMax, Locator}

过

{{p, {1, 1}}, Locator}

但它的行为完全错误。

更新

感谢大家，这是我的最终解决方案：

Manipulate[
 distr1 = BinormalDistribution[p1, {1, 1}, \[Rho]1];
 distr2 = BinormalDistribution[p2, {1, 1}, \[Rho]2];
 Grid[
  {
   {Graphics[{Locator[p1], Locator[p2]}, 
     PlotRange -> {{-5, 5}, {-5, 5}}]},
   {Plot3D[{PDF[distr1, {x, y}], PDF[distr2, {x, y}]}, {x, -5, 5}, {y, -5, 5}, PlotRange -> All]}
   }],
 {{\[Rho]1, 0}, -0.9, 0.9}, {{\[Rho]2, 0}, -0.9, 0.9},
 {{p1, {1, 1}}, Locator},
 {{p2, {1, 1}}, Locator}
 ]

更新

现在的问题是我无法调整和旋转下部 3d 图形的 。有谁知道如何解决这个问题？ 我回到了带有两个 Slider2D 对象的解决方案。

Answer 1

如果您检查 InputForm，您会发现 GraphicsGrid 返回一个 Graphics 对象。因此，定位器确实在整个图像中移动。

GraphicsGrid[{{Graphics[Circle[]]}, {Graphics[Disk[]]}}] // InputForm

如果您只是将 GraphicsGrid 更改为 Grid，定位器将被限制在第一部分，但结果看起来仍然有点奇怪。你的 PlotRange 规范有点奇怪；它似乎不符合文档中心指定的任何格式。也许你想要类似下面的东西。

Manipulate[
 Grid[{
   {Graphics[Locator[p], Axes -> True,
     PlotRange -> {{-3, 3}, {-3, 3}}]},
   {Graphics[Line[{{0, 0}, p}], Axes -> True,
     PlotRange -> {{-3, 3}, {-3, 3}}]}},
  Frame -> All],
 {{p, {1, 1}}, Locator}]

Answer 2

LocatorPane[] 在将定位器限制在某个区域方面做得很好。

这是巫师先生使用的方法的一种变体。

Column[{ LocatorPane[Dynamic[pt3],
   Framed@Graphics[{}, ImageSize -> 150, PlotRange -> 3]],
   Framed@Graphics[{Line[{{-1, 0}, Dynamic@pt3}]}, ImageSize -> {150, 150}, 
     PlotRange -> 3]}]

我假设您希望定位器与其控制的线路共享空间。其实就是“附”在一线。事实证明，这更容易实现。

Column[{LocatorPane[Dynamic[pt3],Framed@Graphics[{Line[{{-1, 0}, Dynamic@pt3}]},
 ImageSize -> 150, PlotRange -> 3]]}]

Answer 3

我不确定你想实现什么目标。我看到了很多问题，但我不知道要解决什么。也许您只想要一个简单的 Slider2D 构造？

DynamicModule[{p = {1, 1}}, 
 Column@{Slider2D[Dynamic[p], {{-3, -3}, {3, 3}}, 
    ImageSize -> {200, 200}], 
   Graphics[Line[{{0, 0}, Dynamic[p]}], 
    PlotRange -> {{-3, 3}, {-3, 3}}, ImageSize -> {200, 200}]}]

---

这是对有关 3D 图形旋转的更新问题的答复。

我相信 David 建议的 LocatorPane 是解决此问题的好方法。我只是输入了一个通用函数，因为您的示例无法在 Mathematica 7 上运行。

DynamicModule[{pt = {{-1, 3}, {1, 1}}},
 Column[{
   LocatorPane[Dynamic[pt], 
     Framed@Graphics[{}, PlotRange -> {{-5, 5}, {-5, 5}}]],
   Dynamic@
    Plot3D[{x^2 pt[[1, 1]] + y^2 pt[[1, 2]],
           -x^2 pt[[2, 1]] - y^2 pt[[2, 1]]},
        {x, -5, 5}, {y, -5, 5}]
 }]
]