在运行时评估 XPath 表达式还是使用不同的方法？

Question

<grid>
<col>Links</col>
<col>Rechts</col>
<row>
    <Links>l1</Links>
    <Rechts>r1</Rechts>
</row>
<row>
    <Links>l2</Links>
    <Rechts>r2</Rechts>
</row>
</grid>

大家好，鉴于上面的 XML 数据，我想创建一个类似以下的表：

Links|Rechts
l1|r1
l2|r2

我的 XSL 模板是：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:dyn="http://exslt.org/dynamic"
extension-element-prefixes="dyn">

    <xsl:template match="grid">

        <xsl:for-each select="//row">
            <xsl:variable name="currentrow" select="."/>
            <xsl:for-each select="//col">
                <xsl:variable name="colname" select="text()"/>
                <xsl:value-of select="dyn:evaluate('$currentrow/$colname/text()')"></xsl:value-of>
            </xsl:for-each>
        </xsl:for-each>
    </xsl:template>

</xsl:stylesheet>

我得到的唯一输出是“”。

我不知道如何解决我的问题。我不知道使用 dyn:evaluate 是否是正确的方法。

感谢您的帮助！

Answer 1

将您的 XSLT grid 部分替换为

<xsl:template match="grid">
    <xsl:for-each select="row">
            <xsl:value-of select="Links"/>|
            <xsl:value-of select="Rechts"/><br>
    </xsl:for-each>
</xsl:template>

我已使用
作为换行符，如果这不是 HTML，请使用相关符号。

Answer 2

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text"/>
  <xsl:strip-space elements="*" />

  <xsl:template match="grid">
    <xsl:apply-templates select="col" />
    <xsl:apply-templates select="row" />
  </xsl:template>

  <xsl:template match="col|row/*">
    <xsl:value-of select="." />
    <xsl:choose>
      <xsl:when test="position() = last()"><xsl:value-of select="'
'" /></xsl:when>
      <xsl:otherwise>|</xsl:otherwise>
    </xsl:choose>
  </xsl:template>
</xsl:stylesheet>

请注意，

• 为此不需要 XPath 的动态评估。
• 删除纯空白文本节点，否则这些文本节点将出现在输出中
• 相同的模板可以匹配不同的节点（此处通过联合运算符 |）
• 这个解决方案可以处理任意数量的列，
• 数据字段的命名方式并不重要，因为我使用了 row/*

---

编辑一个更详细的版本，不假设每列都会在那里。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text"/>
  <xsl:strip-space elements="*" />

  <xsl:template match="grid">
    <xsl:apply-templates select="col" />
    <xsl:apply-templates select="row" />
  </xsl:template>

  <xsl:template match="col">
    <xsl:value-of select="." />
    <xsl:call-template name="separator" />
  </xsl:template>

  <xsl:template match="row">
    <xsl:variable name="this" select="." />
    <xsl:for-each select="/grid/col">
      <xsl:value-of select="$this/*[name() = current()]" />
      <xsl:call-template name="separator" />
    </xsl:for-each>
  </xsl:template>

  <xsl:template name="separator">
    <xsl:choose>
      <xsl:when test="position() = last()"><xsl:value-of select="'
'" /></xsl:when>
      <xsl:otherwise>|</xsl:otherwise>
    </xsl:choose>
  </xsl:template>
</xsl:stylesheet>

Answer 3

此样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:variable name="vColNames" select="/grid/col"/>
    <xsl:template match="grid">
        <table>
            <xsl:apply-templates/>
        </table>
    </xsl:template>
    <xsl:template match="col"/>
    <xsl:template match="col[1]">
        <tr>
            <xsl:apply-templates select="../col" mode="wrap"/>
        </tr>
    </xsl:template>
    <xsl:template match="col" mode="wrap">
        <th>
            <xsl:apply-templates/>
        </th>
    </xsl:template>
    <xsl:template match="row">
        <xsl:variable name="vCurrent" select="."/>
        <tr>
            <xsl:for-each select="$vColNames">
                <xsl:apply-templates select="$vCurrent/*[name()=current()]"/>
            </xsl:for-each>
        </tr>
    </xsl:template>
    <xsl:template match="row/*">
        <td>
            <xsl:apply-templates/>
        </td>
    </xsl:template>
</xsl:stylesheet>

输出：

<table>
    <tr>
        <th>Links</th>
        <th>Rechts</th>
    </tr>
    <tr>
        <td>l1</td>
        <td>r1</td>
    </tr>
    <tr>
        <td>l2</td>
        <td>r2</td>
    </tr>
</table>

注意：迭代行上下文中的列名称。

Answer 4

此转换（模板数量最少 - 仅 3 个，比所有其他当前解决方案都短，并且能够适应元素顺序或缺少 col 元素）：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="col[not(position()=last())]">
   <xsl:value-of select="concat(.,'|')"/>
 </xsl:template>

 <xsl:template match="row">
  <xsl:text>
</xsl:text>
  <xsl:apply-templates select="/*/col"
       mode="buildCell">
   <xsl:with-param name="pRow" select="."/>
  </xsl:apply-templates>
 </xsl:template>

 <xsl:template match="col" mode="buildCell">
   <xsl:param name="pRow"/>

   <xsl:value-of select=
    "concat($pRow/*[name()=current()],
            substring('|', (position()=last())+1)
           )
    "/>
 </xsl:template>
</xsl:stylesheet>

当应用于提供的 XML 文档时：

<grid>
    <col>Links</col>
    <col>Rechts</col>
    <row>
        <Links>l1</Links>
        <Rechts>r1</Rechts>
    </row>
    <row>
        <Links>l2</Links>
        <Rechts>r2</Rechts>
    </row>
</grid>

产生所需的正确结果：

Links|Rechts
l1|r1
l2|r2