OLE 自动化：如何在不使用剪贴板的情况下在 Word 文档之间复制文本

Question

在使用 Delphi XE 进行一些 Word 自动化时，我同时打开了两个文档。我想将一个文档的给定范围的内容复制到另一个文档中的另一个范围。我该怎么做？

考虑以下代码：

procedure TForm1.ManipulateDocuments;
var
  vDoc1,vDoc2 : TWordDocument;
  vFilename : olevariant;
  vRange1,vRange2 : Range;
begin
  vDoc1 := TWordDocument.Create(nil);
  vDoc2 := TWordDocument.Create(nil);
  try
    vFilename := 'c:\temp\test1.doc';
    vDoc1.ConnectTo(FWordApp.Documents.Open(vFilename,EmptyParam,EmptyParam,EmptyParam,EmptyParam,EmptyParam,EmptyParam,EmptyParam,EmptyParam,EmptyParam,EmptyParam,EmptyParam,EmptyParam,EmptyParam,EmptyParam));

    vFilename := 'c:\temp\test2.doc';
    vDoc2.ConnectTo(FWordApp.Documents.Open(vFilename,EmptyParam,EmptyParam,EmptyParam,EmptyParam,EmptyParam,EmptyParam,EmptyParam,EmptyParam,EmptyParam,EmptyParam,EmptyParam,EmptyParam,EmptyParam,EmptyParam));

    vRange1 := GetSourceRange(vDoc1);
    vRange2 := GetDestinationRange(vDoc2);

    vRange2.CONTENTS := vRange1.CONTENTS; //What should I substitute for CONTENTS?
  finally
    vDoc1.Free;
    vDoc2.Free;
  end;
end;

有什么东西可以代替 CONTENTS 吗？我无法使用文本，因为我想复制格式、书签、字段代码等。我是否必须以另一种方式进行操作？有什么建议吗？

Answer 1

我不知道适用于早期版本的 Word 的方法，但对于较新版本（2007 及更高版本），您可以 将文档范围导出到片段文件，然后从另一个文档导入它。如果你想要早期绑定，你可能需要导入类型库（msword.olb），我不知道Delphi XE是否有。否则，代码可能如下所示：

function GetTempFileName(Prefix: string): string;
begin
  SetLength(Result, MAX_PATH);
  GetTempPath(MAX_PATH, PChar(Result));
  windows.GetTempFileName(PChar(Result), PChar(Prefix), 0, PChar(Result));
end;

procedure TForm2.Button1Click(Sender: TObject);
const
//  wdFormatDocument = 0;
  wdFormatRTF = $00000006;
var
  WordApp : OleVariant;
  fragment: string;
  vDoc1, vDoc2: OleVariant;
  vRange1, vRange2: OleVariant;
begin
  try
    WordApp := GetActiveOleObject('Word.Application');
  except
    WordApp := CreateOleObject('Word.Application');
  end;
  WordApp.Visible := True;

  vDoc1 := WordApp.Documents.Open(ExtractFilePath(Application.ExeName) + 'test1.doc');
  vRange1 := vDoc1.Range(20, 120);     // the export range
  fragment := GetTempFileName('frg');
  vRange1.ExportFragment(fragment, wdFormatRTF);
  try
    vDoc2 := WordApp.Documents.Open(ExtractFilePath(Application.ExeName) + 'test2.doc');
    vRange2 := vDoc2.Range(15, 15);    // where to import
    vRange2.ImportFragment(fragment);
  finally
    DeleteFile(fragment);
  end;
end;

在我的测试中，“文档”格式引发了错误（例如无法插入 XML 格式），因此使用 RTF 格式。

编辑：

在早期版本中，似乎可以将一个文档中的命名选区插入到另一个文档中的选区中。如果其中一个选择恰好位于某些文本的中间，则结果在格式方面似乎并不完美。但除此之外，它似乎运作良好。

  ...
  WordApp.Visible := True;

  vDoc1 := WordApp.Documents.Open(ExtractFilePath(Application.ExeName) + 'test1.doc');
  vRange1 := vDoc1.Range(20, 188);                 // the transfer range
  vDoc1.Bookmarks.Add('TransferSection', vRange1); // arbitrary bookmark name

  vDoc2 := WordApp.Documents.Open(ExtractFilePath(Application.ExeName) + 'test2.doc');
  vRange2 := vDoc2.Range(103, 104);           // where to import the bookmark
  vRange2.Select;
  vDoc2.ActiveWindow.Selection.InsertFile(vDoc1.FullName, 'TransferSection');

  vDoc1.Bookmarks.Item('TransferSection').Delete; // no need for the bookmark anymore
 

Answer 2

如果您可以使用 Office Open XML 格式（即 中引入的 docx 文件格式） Word 2007），那么您无需自动化即可完成此操作。

2007 年之前的 Word 版本必须安装 兼容包 它将启用 Word 2003、2002 和 2000 的 docx 文件。docx

文件实际上是一个包含多个 xml 文件的 zip 文件。尝试将 docx 文件的扩展名从 .docx 更改为 .zip 并在例如中打开该文件。 WinZip。

所以...解压缩 docx 文件并获取您需要的 xml 部分。作为纯字符串或作为 xml 文档。然后您可以将此 xml 部分注入到其他 docx 文件中。不过，您需要知道 xml 结构中的何处来抓取/插入 xml。这取决于您对文档结构的了解程度以及允许用户在文档中进行的编辑程度。

我不知道 Word 将如何使用这种方法处理重复的书签名称等。

Answer 3

看来我在深入研究类似问题时找到了这个问题的规范解决方案。 Range 对象的 FormattedText 属性正是您所需要的。只需使用：

vRange2.FormattedText := vRange1;

vRange1 的内容将被复制到 vRange2 中。另外，这也有效：

vRange2 := vRange1;

尽管如此，第二条语句不会复制格式。

Answer 4

为什么不使用剪贴板？如果在 vDoc1 中选择了所有文本，则要将其复制到剪贴板只需要一个简单的调用：vDoc1.copy。同样，将剪贴板的内容复制到第二个文档需要一个简单的调用：vDoc2.paste。剪贴板缓冲区将保存所有格式信息。