C++到 F# 平滑翻译

Question

大家好，我有以下 C++ 代码。

for (int i=0; i < nObstacles; i++)
{
  int x,y;
  bool bAlreadyExists;
  do {          
    x = rand() % nGridWidth;
    y = rand() % nGridHeight;                   
  } while (HasObstacle(x, y));
  SetObstacle(x, y, true);      
}

我可以毫无问题地直接将其转换为 F#。

let R = new System.Random()
for i=0 to nObstacles do
        let mutable bGoodToGo = false;
        let mutable x =0;
        let mutable y = 0
        while not bGoodToGo do
            x <-R.Next(nWidth)
            y <-R.Next(nHeight)
            bGoodToGo <- IsEmptyAt x y
        board.[x,y]<-Obstacle;

当然，这可能会让大多数人感到畏缩，因为这不是 F# 的使用方式。此代码具有一些 F# 的“不合规矩”概念，例如 do-while 循环和可变数据。

但我有兴趣看到的是具有不可变数据的“正确”F# 翻译，以及某种 do-while 等价物。

Answer 1

第一步，您可以了解如何简化 for 循环内的 while 循环。一种选择是使用 Seq.initInfinite 生成一个序列，该序列将为您提供任意数量的随机 X、Y 坐标。然后，您可以使用 Seq.find 查找第一个引用空板字段的值。

我还更改了 isEmpty 以获取元组（以便您可以使用部分函数应用程序将其作为参数传递给 Seq.find），并且更改了一些名称以遵循更标准的 F# 风格（您通常不会使用匈牙利命名符号）：

let isEmpty (x, y) = board.[x,y] = -1

let rnd = new System.Random()
for i = 0 to obstacleCount do
  let x, y =
    // Generate infinite sequence of random X Y coordinates
    Seq.initInfinite (fun _ -> rnd.Next(width), rnd.Next(height))
    // Find first coordinate that refers to empty field
    |> Seq.find isEmpty
  // We still have mutation here
  board.[x,y] <- Obstacle

我认为这是非常优雅的功能解决方案。它可能比命令式解决方案慢一点，但重点是函数式风格使编写和使用变得更容易。一旦你学会了它，就改变它的实现（你总是可以使用命令式风格作为优化）。

为了避免所有可变状态，您需要首先生成障碍物的位置，然后初始化数组。例如，您可以递归地将新坐标添加到集合中，直到达到所需的长度。然后，您可以使用 Array2D.init 生成数组：

let rec generateObstacles obstacles =
  if Set.count obstacles = obstacleCount then obstacles
  else 
    // Try generating new coordinate and add it to the set
    // (if it is already included, this doesn't do anything)
    obstacles
    |> Set.add (rnd.Next(width), rnd.Next(height))
    |> generateObstacles

let obstacles = generateObstacles Set.empty
Array2D.init width height (fun x y -> 
  if obstacles.Contains(x, y) then Obstacle else Empty)

这实际上并不短，而且会慢一些，所以我会坚持使用第一个解决方案。然而，这是一个很好的练习，展示了递归和集合......

Answer 2

这是我的尝试：

Seq.initInfinite (fun _ -> rnd.Next(width), rnd.Next(height))
|> Seq.filter (fun (x, y) -> IsEmptyAt x y)
|> Seq.distinct
|> Seq.take nObstacles
|> Seq.iter (fun (x, y) -> board.[x,y] <- Obstacle)

如果板一开始是空的，您可以删除 Seq.filter。就像托马斯的解决方案一样，它生成无限的位置序列。然后，它会删除错误和重复的位置。最后，它用 nObstacles 第一个元素更新棋盘。