如何在TWebBrowser中捕获页面区域？

Question

我正在尝试制作一个程序，该程序可以对加载到 TWebBrowser 组件内的网站上的各个区域进行屏幕截图。

到目前为止，我只找到了“如何制作整个页面的屏幕截图”的解决方案，但我无法让它捕获特定区域，它只是向任何方向拉伸页面。

http://www.delphifaq.com/faq/f408.shtml

我一直在使用上面网站中提供的代码。

有没有办法修改代码，使其能够满足我的需要？我尝试过，但失败了。

如果有人至少能给我一个如何解决这个问题的指导，我将不胜感激。

谢谢

Answer 1

我建议改用 HTML Elemwnt 的 IHTMLElementRender 接口。您可以轻松找到光标下的元素并将其渲染为位图。

在我的 TWebBrowser descant 中，我是这样实现的：

function TWebBrowserIBMA.ElementAsBitmap(pElement : IHTMLElement2) : TBitmap;
var
  pRender       : IHTMLElementRender;
  oBmpPart      : TBitmap;
  nClientWidth  : Integer;
  nClientHeight : Integer;
  nX            : Integer;
  nLastX        : Integer;
  bDoneX        : Boolean;
  nY            : Integer;
  nLastY        : Integer;
  bDoneY        : Boolean;
begin
  Result := TBitmap.Create;

  try
    Result.Height := pElement.scrollHeight;
    Result.Width  := pElement.scrollWidth;
  except
    exit;
  end;

  LockWindowUpdate(Handle);

  if (pElement.QueryInterface(IID_IHTMLElementRender, pRender) = S_OK) then begin
    try
      oBmpPart        := TBitmap.Create;
      oBmpPart.Width  := pElement.scrollWidth;
      oBmpPart.Height := pElement.scrollHeight;
      nClientWidth    := pElement.clientWidth;
      nClientHeight   := pElement.clientHeight;

      try
        nX      := pElement.scrollWidth; 
        nLastX  := -1;
        bDoneX  := false;

        while not bDoneX do begin
          pElement.scrollLeft := nX;
          nX := pElement.scrollLeft;
          if nLastX = -1 then begin
            nLastX := nX + nClientWidth;
          end;
          nY     := pElement.scrollHeight;
          nLastY := (-1);
          bDoneY := false;

          while not bDoneY do begin
            pElement.scrollTop := nY;
            nY := pElement.scrollTop;

            if nLastY = -1 then begin
              nLastY := nY + nClientHeight;
            end;

            if (pRender.DrawToDC(oBmpPart.Canvas.Handle) = S_OK) then begin
              BitBlt(Result.Canvas.Handle, nX, nY, nLastX-nX, nLastY-nY, oBmpPart.Canvas.Handle, 2, 2,SRCCOPY);
            end;

            bDoneY  := (nY = 0);
            nLastY  := nY;
            Dec(nY, nClientHeight-4);  
          end;

          bDoneX  := (nX = 0);
          nLastX  := nX;
          Dec(nX, (nClientWidth-4));
        end;
      finally
        FreeAndNil(oBmpPart);
      end;
    finally
      pRender := nil;
    end;
  end;

  LockWindowUpdate(0);
end;

Answer 2

您可以使用 sourceBitmap.Canvas.CopyRect

Answer 3

您是否尝试过将 sourceDrawRect 设置为一个矩形，其顶部和左侧为负，右侧和底部超过您让视图对象绘制的位图的宽度和高度，以便您想要的区域落在此上位图？