如何一次打印成两个文件？

Question

我无法让这行代码正常工作：

for my $fh (FH1, FH2, FH3) { print $fh "whatever\n" }

我在 perldoc 但它对我不起作用。

到目前为止，我的代码是：

my $archive_dir = '/some/cheesy/dir/';
my ($stat_file,$stat_file2) = ($archive_dir."file1.txt",$archive_dir."file2.txt");
my ($fh1,$fh2);

for my $fh (fh1, fh2) { print $fh "whatever\n"; }

我在 (fh1, fh2) 部分收到“Bareword”错误，因为我使用的是 strict。我还注意到他们在示例中缺少 ; ，所以我猜测除此之外可能还有更多错误。

一次打印到两个文件的正确语法是什么？

Answer 1

你还没有打开这些文件。

my ($fh1,$fh2);
open($fh1, ">", $stat_file) or die "Couldn't open $stat_file: $!";
open($fh2, ">", $stat_file2) or die "Couldn't open $stat_file2: $!";

for my $fh ($fh1, $fh2) { print $fh "whatever\n"; }

请注意，我没有使用裸词。在过去，您可能会使用：

open(FH1, ">$stat_file");
...
for my $fh (FH1, FH2) { print $fh "whatever\n"; }

但现代的方法是前者。

Answer 2

我只会使用 IO::Tee。

use strict;
use warnings;
use autodie; # open will now die on failure
use IO::Tee;

open my $fh1, '>', 'file1';
open FH2, '>', 'file2';

my $both = IO::Tee->new( $fh1, \*FH2 );

print {$both} 'This is file number ';

print {$fh1} 'one';
print FH2    'two';

print {$both} "\n";
print {$both} "foobar\n";

$both->close;

运行上述程序会产生：

file1

This is file number one
foobar

file2

This is file number two
foobar

我建议阅读整个 perldoc 文件更高级的用法。

Answer 3

看起来不错，只是以前在 Perl 中使用裸字作为文件句柄很常见，但现在建议使用普通标量。

因此，请确保您确实打开了文件，然后只需将 (fh1, fh2) 部分替换为实际的文件句柄（即 ($fh1, $fh2) > 或者什么）

Answer 4

另一个版本基于布莱恩的回答：

open(my $fh1, ">", $stat_file) or die "Couldn't open $stat_file!";
open(my $fh2, ">", $stat_file2) or die "Couldn't open $stat_file2!";
for ($fh1, $fh2) { print $_ "whatever\n"; }

Answer 5

您首先需要打开文件以获得有效的文件句柄

open (MYFILEA, $stat_file);
open (MYFILEB, $stat_file2);
for my $fh ( \*MYFILEA, \*MYFILEB ) { print $fh "whatever\n" } 
close (MYFILEA);
close (MYFILEB);