vb.net 如何制作一个只有通知图标而没有 Windows 窗体的应用程序？

Question

我想制作一个只有通知图标并且启动时没有任何可见窗口窗体的应用程序。我看到一些类似于我想要为 c# 做的示例，但我不知道如何在 vb.net 项目中执行此操作。

Answer 1

表格并不是绝对必要的。您可以实例化 NotifyIcon 并使用它，而无需创建表单：

Public Class AppContext
    Inherits ApplicationContext

    Private notifyIcon As NotifyIcon
    Private appActive As Boolean

    Public Sub New()
        AddHandler Application.ApplicationExit, AddressOf OnApplicationExit

        notifyIcon = New NotifyIcon()
        notifyIcon.Icon = My.Resources.ActiveIcon
        notifyIcon.Text = "The app is active."

        AddHandler notifyIcon.MouseClick, AddressOf OnIconMouseClick

        appActive = True
        notifyIcon.Visible = True

    End Sub

    Private Sub OnApplicationExit(ByVal sender As Object, ByVal e As EventArgs)
        If notifyIcon IsNot Nothing Then
            notifyIcon.Dispose()
        End If
    End Sub

    Private Sub OnIconMouseClick(ByVal sender As Object, ByVal e As MouseEventArgs)

        If e.Button = MouseButtons.Left Then
            appActive = Not appActive
            notifyIcon.Icon = If(appActive, My.Resources.ActiveIcon, My.Resources.InactiveIcon)
            notifyIcon.Text = If(appActive, "The app is active.", "The app is not active.")
        Else
            If MsgBox("Do you want to Exit?", MsgBoxStyle.YesNo) = MsgBoxResult.Yes Then
                notifyIcon.Visible = False
                ExitThread()
            End If
        End If
    End Sub

End Class

然后从 Sub Main 启动您的应用程序：

Public Module EntryPoint
    Public Sub Main()
        Dim ctx As New AppContext()
        Application.Run(ctx)
    End Sub
End Module

Answer 2

只需将表单设置为透明并将其大小调整为 1x1..
并添加一个通知图标..

并在表单加载事件上执行以下操作：

NotifyIcon.Visible = True

然后进行您想要的操作..

您可以创建一个上下文菜单条（右键单击它时的菜单）
PS：如果你这样做，你需要进入 NotifyIcon 属性并将上下文菜单条设置为你创建的..

希望它对你有帮助..