在 Mathematica 中绘制复函数

Question

如何制作复制 行为的 Mathematica 图形鼠尾草中的complex_plot？ IE

...采用 1 的复函数 变量，并绘制输出 在指定的 xrange 上运行并且 yrange 如下所示。这 输出的幅度被指示 由亮度（零为 黑色且无穷大为白色）而 参数由色调表示 （红色为正实数，并且 通过橙色、黄色、...增加 随着参数的增加）。

这是 zeta 函数的示例（从 Neutral Drifts 的 M. Hampton 盗取），具有绝对值的重叠轮廓:

在 Mathematica 文档页面 Functions Of Complex Variables 它说您可以使用 ContourPlot 和 DensityPlot 可视化复杂函数“可能着色按阶段”。但问题在于两种类型的绘图中，ColorFunction 仅采用等于该点处的轮廓或密度的单个变量 - 因此在绘制绝对值时似乎不可能使其对相位/参数进行着色。请注意，这对于 Plot3D 来说不是问题，其中所有 3 个参数 (x,y,z) 都传递给 ColorFunction。

我知道还有其他方法可以可视化复杂函数 - 例如 Plot3D 文档，但这不是我想要的。

另外，我确实有下面的一个解决方案（实际上被用来生成维基百科中使用的一些图形），但它定义了一个相当低级的函数，我认为使用像 ContourPlot 或 DensityPlot 这样的高级函数应该是可能的>。但这并不应该阻止您提供您最喜欢的使用较低级别构造的方法！

---

编辑： Michael Trott 在 Mathematica 杂志上发表了一些不错的文章：
可视化代数函数的黎曼曲面，IIa, IIb，IIc，IId。
可视化黎曼曲面演示。
黎曼曲面的回归（Mma v6 的更新）

当然，Michael Trott 写了Mathematica 指南，其中包含许多漂亮的图形，但似乎已经落后于加速 Mathematica 发布时间表！

Answer 1

这是我的尝试。我对颜色函数做了一些修改。

ParametricPlot[
 (*just need a vis function that will allow x and y to be in the color function*)
 {x, y}, {x, -6, 3}, {y, -3, 3},

 (*color and mesh functions don't trigger refinement, so just use a big grid*)
 PlotPoints -> 50, MaxRecursion -> 0, Mesh -> 50,

 (*turn off scaling so we can do computations with the actual complex values*)
 ColorFunctionScaling -> False,

 ColorFunction -> (Hue[
     (*hue according to argument, with shift so arg(z)==0 is red*)
     Rescale[Arg[Zeta[# + I #2]], {-Pi, Pi}, {0, 1} + 0.5], 1,

     (*fudge brightness a bit: 
       0.1 keeps things from getting too dark, 
       2 forces some actual bright areas*)
     Rescale[Log[Abs[Zeta[# + I #2]]], {-Infinity, Infinity}, {0.1, 2}]] &),

 (*mesh lines according to magnitude, scaled to avoid the pole at z=1*)
 MeshFunctions -> {Log[Abs[Zeta[#1 + I #2]]] &},

 (*turn off axes, because I don't like them with frames*)
 Axes -> False
 ]

我还没有想到一个让网格线改变颜色的好方法。最简单的可能是使用 ContourPlot 而不是 MeshFunctions 生成它们。

Answer 2

这是我对 Axel Boldt 给出的函数的变体，他的灵感来自Jan Homann。两个链接到的页面都有一些漂亮的图形。

ComplexGraph[f_, {xmin_, xmax_}, {ymin_, ymax_}, opts:OptionsPattern[]] := 
 RegionPlot[True, {x, xmin, xmax}, {y, ymin, ymax}, opts, 
  PlotPoints -> 100, ColorFunctionScaling -> False,
  ColorFunction -> Function[{x, y}, With[{ff = f[x + I y]}, 
    Hue[(2. Pi)^-1 Mod[Arg[ff], 2 Pi], 1, 1 - (1.2 + 10 Log[Abs[ff] + 1])^-1]]]
 ]

来绘制没有轮廓的图

ComplexGraph[Zeta, {-7, 3}, {-3, 3}]

然后我们可以通过运行

我们可以通过复制 Brett 通过在 ComplexGraph 中使用和显示特定的绘图网格：

ComplexGraph[Zeta, {-7, 3}, {-3, 3}, Mesh -> 30, 
 MeshFunctions -> {Log[Abs[Zeta[#1 + I #2]]] &},
 MeshStyle -> {{Thin, Black}, None}, MaxRecursion -> 0]

或与等高线图

ContourPlot[Abs[Zeta[x + I y]], {x, -7, 3}, {y, -3, 3}, PlotPoints -> 100,
 Contours -> Exp@Range[-7, 1, .25], ContourShading -> None];
Show[{ComplexGraph[Zeta, {-7, 3}, {-3, 3}],%}]

Answer 3

这不是一个正确的答案，有两个原因：

• 这不是你要求的
• 我无耻地使用布雷特的代码

无论如何，对我来说以下内容更容易解释（亮度是......好吧，只是亮度）：

Brett 的代码几乎完好无损：

Plot3D[
 Log[Abs[Zeta[x + I y]]], {x, -6, 3}, {y, -3, 3},
 (*color and mesh functions don't trigger refinement,so just use a big grid*)
 PlotPoints -> 50, MaxRecursion -> 0, 
 Mesh -> 50, 
 (*turn off scaling so we can do computations with the actual complex values*)
 ColorFunctionScaling -> False, 
 ColorFunction -> (Hue[
     (*hue according to argument,with shift so arg(z)==0 is red*)
     Rescale[Arg[Zeta[# + I #2]], {-Pi, Pi}, {0, 1} + 0.5], 
     1,(*fudge brightness a bit:
     0.1 keeps things from getting too dark,
     2 forces some actual bright areas*)
     Rescale[Log[Abs[Zeta[# + I #2]]], {-Infinity, Infinity}, {0.1, 2}]] &),
     (*mesh lines according to magnitude,scaled to avoid the pole at z=1*)
     MeshFunctions -> {Log[Abs[Zeta[#1 + I #2]]] &},
     (*turn off axes,because I don't like them with frames*)
     Axes -> False]

Answer 4

对于每个有兴趣在 Python 中实现此目标的人，我创建了 cplot。安装

pip install cplot

此绘制 domain-coloring 图en.wikipedia.org/wiki/Taylor_series" rel="nofollow noreferrer">exp 6 次泰勒多项式：

import cplot


def exp_taylor(z):
    s = 1.0
    t = 1.0
    for k in range(1, 7):
        t *= z / k
        s += t
    return s

plt = cplot.plot(
    exp_taylor,
    # or something simpler
    # lambda z: z ** 6 + 1,
    (-5, +5, 400),
    (-5, +5, 400),
)
plt.show()