XSL 如果需要帮助请

Question

我正在将 html 表单转换为 xml 序列，我使用递归函数来实现此目的，

因此参数“list”的输入将采用以下形式

name=value&name=value&name=value

下面的模板可以很好地完成此操作并返回一个 xml 序列，如下所示

<name>value</name><name>value</name><name>value</name>

好的，所以问题 一些名称值对是特殊的，我想向它们添加一个属性，因此输出将是这样，

<name>value</name><name attr="special">value</name><name>value</name>

为此我有一个外部 xml 文件，其中包含特殊名称列表，如下所示

<settings><google><option from="color"/><option from="size"/></google></settings>

所以如果我们假设我有一个 xsl 变量连接到上面这个外部文档的 $SETTINGS

<xsl:for-each select="$SETTINGS/google/option"></xsl:for-each>

应该是有 2 个子节点的节点，其中 1 个称为 color，另一个大小

我想做的是，如果这些子节点中的 1 个名称 = $name 添加类似

<xsl:template name="tokenize">

        <xsl:param name="list"/> 

        <xsl:variable name="seperator" select="'&amp;'"/>

        <xsl:variable name="first" select="substring-before(concat($list, $seperator), $seperator)"/>
        <xsl:variable name="butfirst" select="substring-after($list, $seperator)"/>

        <xsl:variable name="name" select="normalize-space(substring-before($first, '='))"/>
        <xsl:variable name="value" select="normalize-space(substring-after($first, '='))"/>

        <xsl:if test="string-length($name)>0 and string-length($value)>0">
            <xsl:element name="{$name}">
                <xsl:for-each select="$SETTINGS/google/option">
                        ----->   <xsl:if test="$name = $SETTINGS/google/option/ckild name">
                         <xsl:attribute name="option"/>
                                 </xsl:if>
                </xsl:for-each>
                <xsl:value-of select="$value"/>
            </xsl:element>
        </xsl:if>

        <xsl:if test="$butfirst">
            <xsl:call-template name="tokenize">
                <xsl:with-param name="list" select="$butfirst"/> 
                <xsl:with-param name="seperator" select="$seperator"/> 
            </xsl:call-template>
        </xsl:if>

    </xsl:template>

非常感谢 蒂姆·道奇森

Answer 1

此样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:variable name="SETTINGS" select="/settings"/>
    <xsl:template match="/">
        <xsl:call-template name="tokenize">
            <xsl:with-param name="pString"
                 select="'color=blue&name=value&size=big'"/>
        </xsl:call-template>
    </xsl:template>
    <xsl:template name="tokenize">
        <xsl:param name="pString"/>
        <xsl:param name="pSeperator" select="'&'"/>
        <xsl:choose>
            <xsl:when test="not($pString)"/>
            <xsl:when test="contains($pString,$pSeperator)">
                <xsl:call-template name="tokenize">
                    <xsl:with-param name="pString"
                         select="substring-before($pString, $pSeperator)"/>
                    <xsl:with-param name="pSeperator" select="$pSeperator"/>
                </xsl:call-template>
                <xsl:call-template name="tokenize">
                    <xsl:with-param name="pString"
                         select="substring-after($pString, $pSeperator)"/>
                    <xsl:with-param name="pSeperator" select="$pSeperator"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:variable name="vName"
                     select="normalize-space(substring-before($pString,'='))"/>
                <xsl:variable name="vValue"
                     select="normalize-space(substring-after($pString,'='))"/>
                <xsl:if test="$vName and $vValue">
                    <xsl:element name="{$vName}">
                        <xsl:if test="$vName = $SETTINGS/google/option/@from">
                            <xsl:attribute name="attr">special</xsl:attribute>
                        </xsl:if>
                        <xsl:value-of select="$vValue"/>
                    </xsl:element>
                </xsl:if>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

使用此输入：

<settings>
    <google>
        <option from="color"/>
        <option from="size"/>
    </google>
</settings>

输出：

<color attr="special">blue</color>
<name>value</name>
<size attr="special">big</size>

注意：节点集比较