XSLT：我可以使用 xslt 更新 xml 节点中的值吗？

Question

例如，我有一个 xml

 <books>
   <book id="1">
     <title id="11" name="Basic XML"/>
     <price id="12" amount="500"/>
     <quantity id="13" number="10"/>
   </book>
 </books>

可以将书名“Basic XML”更新为“Basic XSLT”或使用 XSLT 更改任何节点的任何其他属性吗？如果是，有人可以给我一些关于如何做到这一点的例子吗？

提前致谢。

Answer 1

此转换：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:my">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <my:reps>
  <repAttr name="name" value="Basic XSLT"/>
  <repAttr name="amount" value="300"/>
  <repAttr name="number" value="20"/>
 </my:reps>

 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match=
   "@*[name()=document('')/*/my:reps/*/@name]">

   <xsl:attribute name="{name()}">
    <xsl:value-of select=
    "document('')/*/my:reps/*[@name=name(current())]/@value"/>
   </xsl:attribute>
 </xsl:template>
</xsl:stylesheet>

应用于提供的 XML 文档时：

<books>
    <book id="1">
        <title id="11" name="Basic XML"/>
        <price id="12" amount="500"/>
        <quantity id="13" number="10"/>
    </book>
</books>

产生所需的正确结果：

<books>
   <book id="1">
      <title id="11" name="Basic XSLT"/>
      <price id="12" amount="300"/>
      <quantity id="13" number="20"/>
   </book>
</books>

说明：

1. 身份规则/模板“按原样”复制每个节点。

2. 身份模板由与任何属性匹配的单个模板覆盖，该属性的名称可以作为在中指定的 repAttr 元素的 name 属性之一的值找到。 my:reps 元素（嵌入 XSLT 样式表中的参数）。

3. 在这种情况下，将使用相同的名称和新值重新创建（而不是复制）该属性，该值在相应的 repAttr 元素（其 value 属性）中指定）。

Answer 2

我无法“更新”输入 Xml，因为 XSLT 纯粹是一种输出驱动技术。它会创建一份新文档，并且无法修改现有文档。

您可以制作几乎相同的副本，但正如 @Oded 评论指出的那样，XSLT 可能有点过分了。 xsl 看起来像（修改后的身份转换）

<xsl:stylesheet version="1.0">
  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>
   <xsl:template match="title/@Name">
     <!-- insert logic here to change the value as appropriate -->
   </xsl:template>
</xsl:stylesheet>