如何在Excel中编辑通过宏代码显示的单元格中的信息？

Question

我有一个宏，这样当您突出显示sheet1上的一行时，该宏就会获取该行中的所有信息，并将其单独显示在sheet2上。如果突出显示sheet1上的不同行，sheet2上的信息将更改以显示该行的信息。

我的问题是，如果我更改sheet2上显示的信息，它不会更改sheet1上的信息。有什么办法可以添加这个功能吗？

我现在有以下代码：

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim myList
If Target.Address <> Target.EntireRow.Address Then Exit Sub
If Target.Rows.Count > 1 Then Exit Sub
myList = [{"B1","B2","B3","B4","B5","B6","B7","B8","B9","B10","B11","B12","B13","B14","B15"}] '<- adjust to your need
With Target.EntireRow
    For i = 1 To UBound(myList)
        Sheets("sheet2").Range(myList(i)).Value = .Cells(i).Value
    Next
End With
End Sub

任何帮助都会很棒！ :)

Answer 1

将sheet1行复制到sheet2后，您还可以记录值来自的原始行#。然后，您可以添加一个额外的宏，将sheet2 值与sheet1 中的值进行比较——然后可以迁移任何更改。

一个可能的基本流程：

• 将sheet1行复制到sheet2（当前宏）
• 将sheet1行#复制到sheet2（即向下一行）
• 在sheet2上进行更改
• 将sheet2行复制到sheet1行（使用sheet2上保存的行#）->这假设不对sheet1 进行任何更改。

Answer 2

您当前正在使用 Worksheet_SelectionChange 事件宏来识别何时完成已选择单行。您需要一个 Worksheet_Change 事件宏，以便 Sheet2 识别何时B1:B15 范围已更改并将更改传递回 Sheet1。

由于 Worksheet_Change 是在值更改时触发的，因此您需要禁用 Application.EnableEvents 属性，以便当您从 Sheet1 的 Worksheet_SelectionChange 子项写入值时不会触发该属性。

您将需要几个公共变量。一个用于记住应返回更改的位置，另一个用于定位 Sheet2 上的目标单元格。这些只能在模块代码表中公开。

Book1 - Module1（代码）

Option Explicit

Public Const sRNG As String = "B1:B15"
Public rRNG As Range

我对原始 Worksheet_SelectionChange 进行了一些小修改，并添加了禁用事件处理的功能。

Book1 - Sheet1（代码）

Option Explicit

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Target.Cells.Count = Columns.Count And Target.Rows.Count = 1 And _
      CBool(Application.CountA(Target)) Then   '<~~ one complete non-blank row 
        On Error GoTo bm_Safe_Exit
        Application.EnableEvents = False
        With Sheet2.Range(sRNG)
            Set rRNG = Target.Cells(1, 1).Resize(.Columns.Count, .Rows.Count)
            .Cells = Application.Transpose(rRNG.Value)
        End With
    End If

bm_Safe_Exit:
    Application.EnableEvents = True
End Sub

工作表.CodeName property 用于标识 Sheet2，因为如果按惯例重命名工作表，该属性不会改变。

目前还不清楚您计划如何识别值更改后要返回到的行。我使用了 Module1 中声明的公共范围类型变量来记录值从 Sheet1 传输到 Sheet2 的最后位置。 Sheet2 上的更改会将它们返回到最后记录的位置。

Book1 - Sheet2（代码）

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Range(sRNG)) Is Nothing Then
        Debug.Print rRNG.Address(0, 0, external:=True)
        On Error GoTo bm_Safe_Exit
        Application.EnableEvents = False
        rRNG = Application.Transpose(Range(sRNG).Value)
    End If

bm_Safe_Exit:
    Application.EnableEvents = True
End Sub

请注意，“记住”的位置仅位于内存中。关闭并重新打开工作簿可以有效地将其“归零”。除非您从 Sheet1 中重新加载了值，否则请勿对 Sheet2 进行更改。