在 XSLT 1.0 中的变量中使用 max

Question

我可以在 XSLT 1 的变量中使用 max 函数吗？ 我需要在某些节点内找到最大值，并且需要从更多地方调用它。 所以我尝试创建一个模板：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:msxsl="urn:schemas-microsoft-com:xslt"
 xmlns:essox="urn:essox-scripts">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:template name="Field001_max_dluznych_splatek">
        <xsl:param name="CrRep"/>
        <xsl:variable name="PocetDluznychSplatekSplatky">
            <xsl:value-of
             select="max($CrRep
                         /Response
                          /ContractData
                           /Installments
                            /InstDetail
                             /NrOfDueInstalments)" />
        </xsl:variable>
        <xsl:variable name="PocetDluznychSplatekKarty">
            <xsl:value-of
             select="max($CrRep
                          /Response
                           /ContractData
                            /Cards
                             /CardDetail
                              /NrOfDueInstalments)" />
        </xsl:variable>
        <xsl:choose>
            <xsl:when test="$PocetDluznychSplatekSplatky
                             &gt;= $PocetDluznychSplatekKarty">
                <xsl:value-of select="$PocetDluznychSplatekSplatky"/>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$PocetDluznychSplatekKarty"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

在 XML Spy 中我收到此错误：

XPath 表达式中的错误未知 功能 - 名称和数量 参数与任何函数都不匹配 静态上下文中的签名 - '最大'。

出了什么问题？ 多谢， 彼得

Answer 1

使用众所周知的最大惯用语：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:msxsl="urn:schemas-microsoft-com:xslt"
 xmlns:essox="urn:essox-scripts">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:template name="Field001_max_dluznych_splatek">
        <xsl:param name="CrRep"/>
        <xsl:variable name="PocetDluznychSplatekSplatky">
            <xsl:call-template name="maximun">
                <xsl:with-param name="pSequence"
                 select="$CrRep
                          /Response
                           /ContractData
                            /Installments
                             /InstDetail
                              /NrOfDueInstalments"/>
            </xsl:call-template>
        </xsl:variable>
        <xsl:variable name="PocetDluznychSplatekSplatky">
            <xsl:call-template name="maximun">
                <xsl:with-param name="pSequence"
                 select="$CrRep
                          /Response
                           /ContractData
                            /Cards
                             /CardDetail
                              /NrOfDueInstalments"/>
            </xsl:call-template>
        </xsl:variable>
        <xsl:choose>
            <xsl:when test="$PocetDluznychSplatekSplatky
                             >= $PocetDluznychSplatekKarty">
                <xsl:value-of select="$PocetDluznychSplatekSplatky"/>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$PocetDluznychSplatekKarty"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
    <xsl:template name="maximun">
        <xsl:param name="pSequence"/>
        <xsl:for-each select="$pSequence">
            <xsl:sort select="." data-type="number" order="descending"/>
            <xsl:if test="position()=1">
                <xsl:value-of select="."/>
            </xsl:if>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

注意：在命名模板中以便重用。

Answer 2

XSLT 1.0 中没有 max 函数。您可以通过按降序对元素进行排序然后获取第一个元素的值来解决此问题。

这是另一种（较慢）的方法：

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:variable name="PocetDluznychSplatekSplatky"
        select="/test/PocetDluznychSplatekSplatky/val[not(../val > .)][1]" />
    <xsl:variable name="PocetDluznychSplatekKarty"
        select="/test/PocetDluznychSplatekKarty/val[not(../val > .)][1]" />
    <xsl:template match="/">
        <xsl:choose>
            <xsl:when
                test="$PocetDluznychSplatekSplatky >= 
                      $PocetDluznychSplatekKarty">
                <xsl:value-of select="$PocetDluznychSplatekSplatky" />
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$PocetDluznychSplatekKarty" />
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

示例源文档：

<test>
    <PocetDluznychSplatekSplatky>
        <val>22</val>
        <val>3241</val>
        <val>13</val>
    </PocetDluznychSplatekSplatky>
    <PocetDluznychSplatekKarty>
        <val>1</val>
        <val>3234341</val>
        <val>13</val>
    </PocetDluznychSplatekKarty>
</test>

输出：

3234341

每个变量的 select 中的 XPath 如下所示：

/test/PocetDluznychSplatekSplatky/val[not(../val > .)][1]

或者，选择没有 的 val 元素>val 具有更大值（即最大值）的同级。

（显然，您需要调整 XPath 以适合您的源文档。）

注意： sort 解决方案的性能要好得多（假设 n*log( n) 排序实现）。第二种方法需要将每个 val 与其每一个同级进行比较，因此是二次的。