grails 中保存和更新方法的习惯用法

Question

grails 中是否有任何习惯用法可以帮助我们保存域对象？

例如

我可能想做类似的事情

if(candidate.hasErrors || !candidate.save)
{
candidate.errors.each {
        log it


}

但是我不想将逻辑传播到我执行domainObject.save 的所有地方。

我也不想要像存储库这样的单独的类，我将这个domainObject传递给它并放入这个逻辑

谢谢 苏达山

Answer 1

这是我用来验证和保存的服务方法，但会在失败时记录已解析的验证消息。使用它而不是仅仅使用 println error 或 log.warn error 会很有帮助，因为错误对象的 toString() 非常冗长，你只想看看会显示什么关于 GSP：

class MyService {
   def messageSource

   def saveOrUpdate(bean, flush = false) {
      return validate(bean) ? bean.save(flush: flush) : null
   }

   boolean validate(bean) {
      bean.validate()
      if (bean.hasErrors()) {
      if (log.isEnabledFor(Level.WARN)) {
         def message = new StringBuilder(
            "problem ${bean.id ? 'updating' : 'creating'} ${bean.getClass().simpleName}: $bean")
         def locale = Locale.getDefault()
         for (fieldErrors in bean.errors) {
            for (error in fieldErrors.allErrors) {
               message.append("\n\t")
               message.append(messageSource.getMessage(error, locale))
            }
         }
         log.warn message
      }
      bean.discard()
      return false
   }

   return true
}

这是控制器中的一个示例：

class MyController {

   def myService

   def actionName = {
      def thing = new Thing(params)
      if (myService.saveOrUpdate(thing)) {
         redirect action: 'show', id: thing.id
      }
      else {
         render view: 'create', model: [thing: thing]
      }
   }
}

编辑：也可以将这些方法添加到 MetaClass，例如在 BootStrap.groovy 中：

class BootStrap {

   def grailsApplication
   def messageSource

   def init = { servletContext ->

      for (dc in grailsApplication.domainClasses) {
         dc.metaClass.saveOrUpdate = { boolean flush = false ->
            validateWithWarnings() ? delegate.save(flush: flush) : null
         }

         dc.metaClass.validateWithWarnings = { ->
            delegate.validate()
            if (delegate.hasErrors()) {
               def message = new StringBuilder(
                  "problem ${delegate.id ? 'updating' : 'creating'} ${delegate.getClass().simpleName}: $delegate")
               def locale = Locale.getDefault()
               for (fieldErrors in delegate.errors) {
                  for (error in fieldErrors.allErrors) {
                     message.append("\n\t")
                     message.append(messageSource.getMessage(error, locale))
                  }
               }
               log.warn message
               delegate.discard()
               return false
            }

            return true
         }
      }
   }
}

这取决于范围内的“log”变量，这在任何 Grails 中都是如此人工制品。这会稍微改变控制器的用法：

class MyController {

   def actionName = {
      def thing = new Thing(params)
      if (thing.saveOrUpdate()) {
         redirect action: 'show', id: thing.id
      }
      else {
         render view: 'create', model: [thing: thing]
      }
   }
}

作为元类方法，重命名它可能更有意义，例如 saveWithWarnings()。